From 3b3ae091c48718f030d0ddfdd3fc51f8fb6ce987 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Thu, 12 Dec 2019 15:24:56 +0100
Subject: dev-libs/libinput: Bump to version 1.14.901

Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 dev-libs/libinput/Manifest                 |  1 +
 dev-libs/libinput/libinput-1.14.901.ebuild | 79 ++++++++++++++++++++++++++++++
 2 files changed, 80 insertions(+)
 create mode 100644 dev-libs/libinput/libinput-1.14.901.ebuild

(limited to 'dev-libs/libinput')

diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index 90987951333e..12894b4169ef 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1 +1,2 @@
 DIST libinput-1.14.3.tar.xz 567560 BLAKE2B 76d38b795a5e721a73062e9c37b23bf6739291549cadc66401ef47b1a9afd5766f1d0ed855fc66912e4257fae4b1b813946c67246adb8d8566d5ad9478079636 SHA512 f01d1bd1b25b8060519575644597d35f0c89de5386d298441f440128ceee3e57549921a058adec31adc8b33dbdedf4c0bd12c76905a69f752859d3136e26336d
+DIST libinput-1.14.901.tar.xz 573900 BLAKE2B ec2561faa4e83fdbef28802295a7a4b458ce147a05213363f7bfb136ae6f144ac3e49ed012a76a4ac19dc0ae9e51b3ecbe266794b7a2f3862788556ef1394a1b SHA512 93d97cefa49f640b7b29ac3f54497d57cd1499cb0945504d4522ed564b2414fda55ece09d9212ca2cc3c911375ce0b6906ae62912fbc501aea5238afad3ad4bc
diff --git a/dev-libs/libinput/libinput-1.14.901.ebuild b/dev-libs/libinput/libinput-1.14.901.ebuild
new file mode 100644
index 000000000000..9e1ab791f12f
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.14.901.ebuild
@@ -0,0 +1,79 @@
+# Copyright 2014-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+[[ "$(ver_cut 3)" -gt 900 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom"
+# Tests require write access to udev rules directory which is a no-no for live system.
+# Other tests are just about logs, exported symbols and autotest of the test library.
+RESTRICT="test"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/commonmark[${PYTHON_USEDEP}]
+			dev-python/recommonmark[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+		')
+		>=app-doc/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+"
+#	test? ( dev-util/valgrind )
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+	>=dev-libs/libevdev-1.3
+	>=sys-libs/mtdev-1.1
+	virtual/libudev:=
+	virtual/udev
+"
+DEPEND="${RDEPEND}"
+#	test? ( >=dev-libs/check-0.9.10 )
+
+python_check_deps() {
+	has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+	has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+	has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		$(meson_use doc documentation)
+		$(meson_use input_devices_wacom libwacom)
+		-Dtests=false # tests are restricted
+		-Dudev-dir="$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/Documentation/.
+	fi
+}
+
+pkg_postinst() {
+	udevadm hwdb --update --root="${ROOT}"
+}
-- 
cgit v1.2.3-65-gdbad