From c022f38e439e408e0e2780190512e81eb26cd009 Mon Sep 17 00:00:00 2001
From: Justin Lecher <jlec@gentoo.org>
Date: Tue, 29 Sep 2015 11:09:27 +0200
Subject: dev-libs/liblinear: Unbundle blas

Package-Manager: portage-2.2.22
Signed-off-by: Justin Lecher <jlec@gentoo.org>
---
 dev-libs/liblinear/liblinear-210-r1.ebuild | 58 ++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-libs/liblinear/liblinear-210-r1.ebuild

(limited to 'dev-libs/liblinear/liblinear-210-r1.ebuild')

diff --git a/dev-libs/liblinear/liblinear-210-r1.ebuild b/dev-libs/liblinear/liblinear-210-r1.ebuild
new file mode 100644
index 000000000000..250995b54042
--- /dev/null
+++ b/dev-libs/liblinear/liblinear-210-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit multilib toolchain-funcs
+
+DESCRIPTION="A Library for Large Linear Classification"
+HOMEPAGE="http://www.csie.ntu.edu.tw/~cjlin/liblinear/ https://github.com/cjlin1/liblinear"
+SRC_URI="https://github.com/cjlin1/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+
+RDEPEND="virtual/blas"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	sed -i \
+		-e '/^AR/s|=|?=|g' \
+		-e '/^RANLIB/s|=|?=|g' \
+		-e '/^CFLAGS/d;/^CXXFLAGS/d' \
+		blas/Makefile || die
+	sed -i \
+		-e 's|make|$(MAKE)|g' \
+		-e '/$(LIBS)/s|$(CFLAGS)|& $(LDFLAGS)|g' \
+		-e '/^CFLAGS/d;/^CXXFLAGS/d' \
+		-e 's|$${SHARED_LIB_FLAG}|& $(LDFLAGS)|g' \
+		-e 's:blas/blas.a::g' \
+		Makefile || die
+}
+
+src_compile() {
+	emake \
+		CC=$(tc-getCC) \
+		CXX=$(tc-getCXX) \
+		CFLAGS="${CFLAGS} -fPIC" \
+		CXXFLAGS="${CXXFLAGS} -fPIC" \
+		AR="$(tc-getAR) rcv" \
+		RANLIB="$(tc-getRANLIB)" \
+		LIBS=$($(tc-getPKG_CONFIG) --libs blas) \
+		lib all
+}
+
+src_install() {
+	dolib ${PN}.so.3
+	dosym ${PN}.so.3 /usr/$(get_libdir)/${PN}.so
+
+	newbin predict ${PN}-predict
+	newbin train ${PN}-train
+
+	doheader linear.h
+
+	dodoc README
+}
-- 
cgit v1.2.3-18-g5258