From eeb706909562fbab1e0139f14b0bb8f53880a5a3 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Wed, 14 Aug 2019 16:03:41 +0200
Subject: dev-libs/libwacom: 0.33 version bump

Package-Manager: Portage-2.3.71, Repoman-2.3.17
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-libs/libwacom/Manifest             |  1 +
 dev-libs/libwacom/libwacom-0.33.ebuild | 50 ++++++++++++++++++++++++++++++++++
 2 files changed, 51 insertions(+)
 create mode 100644 dev-libs/libwacom/libwacom-0.33.ebuild

(limited to 'dev-libs/libwacom')

diff --git a/dev-libs/libwacom/Manifest b/dev-libs/libwacom/Manifest
index c77305410958..e684231e15ef 100644
--- a/dev-libs/libwacom/Manifest
+++ b/dev-libs/libwacom/Manifest
@@ -1 +1,2 @@
 DIST libwacom-0.30.tar.gz 119261 BLAKE2B 4f76fcbed42c5453701e3b5dda880a26f9956a803827584aeaf080196b26bedb65f6bdccb7ffe18e7f93861dfee8a633894869b1ea4f6b95e72d64273087b60c SHA512 952ead4b39461d64d9592d0e05824669d0a8bc721aced46f5a99832da0fc63a4023f9803d416ceaf71dc7182660d05d45b799424bca7f54128fa7c44447b688b
+DIST libwacom-0.33.tar.bz2 503217 BLAKE2B 034b06495209cc88e9a3131a8a23b35fdadf8bc038ff9db62d4dc05b31657d1cfbe4856cf7b1a6112c97d47bb532b664e4e59c3b00a2aebf14dfacbcac141063 SHA512 de4d9cf3b5f4d87a159ba8ee617bafce9d13b67dc23d9dc67efd57317b0df2079dd0de328bc800de47f14ee49ea82bb842e34297cef23ba336c1ddca3afa826d
diff --git a/dev-libs/libwacom/libwacom-0.33.ebuild b/dev-libs/libwacom/libwacom-0.33.ebuild
new file mode 100644
index 000000000000..0b1c33cddfbf
--- /dev/null
+++ b/dev-libs/libwacom/libwacom-0.33.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools udev
+
+DESCRIPTION="Library for identifying Wacom tablets and their model-specific features"
+HOMEPAGE="https://github.com/linuxwacom/libwacom"
+SRC_URI="https://github.com/linuxwacom/${PN}/releases/download/${P}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc static-libs"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="
+	dev-libs/glib:2
+	virtual/libgudev:=
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	if ! use doc; then
+		sed -e 's:^\(SUBDIRS = .* \)doc:\1:' -i Makefile.am || die
+	fi
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_install() {
+	use doc && HTML_DOCS=( doc/html/. )
+	default
+	local udevdir="$(get_udevdir)"
+	dodir "${udevdir}/rules.d"
+	# generate-udev-rules must be run from inside tools directory
+	pushd tools > /dev/null || die
+	./generate-udev-rules > "${ED}/${udevdir}/rules.d/65-libwacom.rules" || \
+		die "generating udev rules failed"
+	popd > /dev/null || die
+	find "${D}" -name '*.la' -type f -delete || die
+}
-- 
cgit v1.2.3