From 6f692f268fdb5ab506c6a31519c78c33083c9f12 Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Sun, 21 Feb 2016 11:45:51 +0100
Subject: dev-libs/link-grammar: Fix java dependency and ensure all phases from
 eclasses are really executed (#574872), it needs swig (#574888), and a few
 more fixes and cosmetic things

Package-Manager: portage-2.2.27
---
 dev-libs/link-grammar/link-grammar-5.3.3-r1.ebuild | 68 ++++++++++++++++++++++
 dev-libs/link-grammar/link-grammar-5.3.3.ebuild    | 65 ---------------------
 2 files changed, 68 insertions(+), 65 deletions(-)
 create mode 100644 dev-libs/link-grammar/link-grammar-5.3.3-r1.ebuild
 delete mode 100644 dev-libs/link-grammar/link-grammar-5.3.3.ebuild

(limited to 'dev-libs')

diff --git a/dev-libs/link-grammar/link-grammar-5.3.3-r1.ebuild b/dev-libs/link-grammar/link-grammar-5.3.3-r1.ebuild
new file mode 100644
index 000000000000..50dcbac8e3bd
--- /dev/null
+++ b/dev-libs/link-grammar/link-grammar-5.3.3-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit autotools eutils gnome2 java-pkg-opt-2 python-any-r1
+
+DESCRIPTION="A Syntactic English parser"
+HOMEPAGE="http://www.abisource.com/projects/link-grammar/ http://www.link.cs.cmu.edu/link/"
+SRC_URI="https://github.com/opencog/${PN}/archive/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="aspell +hunspell java python static-libs threads"
+
+RDEPEND="
+	aspell? ( app-text/aspell )
+	hunspell? ( app-text/hunspell )
+	java? (
+		>=virtual/jdk-1.6:*
+		dev-java/ant-core )
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}
+	dev-lang/swig:0
+"
+
+S="${WORKDIR}/${PN}-${P}"
+
+pkg_setup() {
+	if use aspell && use hunspell; then
+		ewarn "You have enabled 'aspell' and 'hunspell' support, but both cannot coexist,"
+		ewarn "only hunspell will be built. Press Ctrl+C and set only 'aspell' USE flag if"
+		ewarn "you want aspell support."
+	fi
+	use java && java-pkg-opt-2_pkg_setup
+	use python && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	use java && java-pkg-opt-2_src_prepare
+	AT_M4DIR="ac-helpers/" eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-perl-bindings \
+		--enable-shared \
+		$(use_enable aspell) \
+		$(use_enable hunspell) \
+		$(usex hunspell --with-hunspell-dictdir=/usr/share/myspell) \
+		$(use_enable java java-bindings) \
+		$(use_enable python python-bindings) \
+		$(use_enable static-libs static) \
+		$(use_enable threads pthreads)
+}
+
+pkg_preinst() {
+	use java && java-pkg-opt-2_pkg_preinst
+	gnome2_pkg_preinst
+}
diff --git a/dev-libs/link-grammar/link-grammar-5.3.3.ebuild b/dev-libs/link-grammar/link-grammar-5.3.3.ebuild
deleted file mode 100644
index dbbbfc4efa8f..000000000000
--- a/dev-libs/link-grammar/link-grammar-5.3.3.ebuild
+++ /dev/null
@@ -1,65 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=5
-PYTHON_COMPAT=( python{2_7,3_4,3_5} )
-
-inherit eutils gnome2 java-pkg-opt-2 python-any-r1
-
-DESCRIPTION="A Syntactic English parser"
-HOMEPAGE="http://www.abisource.com/projects/link-grammar/ http://www.link.cs.cmu.edu/link/"
-SRC_URI="https://github.com/opencog/${PN}/archive/${P}.tar.gz"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
-
-IUSE="aspell +hunspell +java python static-libs threads"
-
-DEPEND="
-	aspell? ( app-text/aspell )
-	hunspell? ( app-text/hunspell )
-	java? ( >=virtual/jdk-1.6:=
-			dev-java/ant-core )
-	${PYTHON_DEPS}"
-
-RDEPEND="${DEPEND}"
-
-pkg_setup() {
-	if use java; then
-		java-pkg-opt-2_pkg_setup
-	fi
-	if use aspell && use hunspell; then
-		ewarn "You have enabled 'aspell' and 'hunspell' support, but both cannot coexist,"
-		ewarn "only aspell will be build. Press Ctrl+C and set only 'hunspell' USE flag if"
-		ewarn "you want hunspell support."
-	fi
-}
-
-src_unpack() {
-	unpack ${A}
-	S=${WORKDIR}/${PN}-${P}
-}
-
-src_prepare() {
-	if use java; then
-		java-pkg-opt-2_src_prepare
-	fi
-	./autogen.sh || die
-}
-
-src_configure() {
-	local myconf
-
-	use hunspell && myconf="${myconf} --with-hunspell-dictdir=/usr/share/myspell"
-	gnome2_src_configure \
-		--enable-shared \
-		$(use_enable aspell) \
-		$(use_enable hunspell) \
-		$(use_enable java java-bindings) \
-		$(use_enable python python-bindings) \
-		$(use_enable static-libs static) \
-		$(use_enable threads pthreads) \
-		${myconf}
-}
-- 
cgit v1.2.3-65-gdbad