From c63980f7bba608bc46a454b484635f281f463b2c Mon Sep 17 00:00:00 2001
From: Amadeusz Żołnowski <aidecoe@gentoo.org>
Date: Tue, 31 May 2016 22:09:30 +0100
Subject: dev-libs/gmime: Add optional support for S/MIME

Fix deps: gpgme is only required for S/MIME, but gmime used to depend on
it unconditionally.

Bump both revisions because the one depending on gtk-sharp is not going
to be stabilized soon.

Gentoo-Bug: 583614

Package-Manager: portage-2.3.0_rc1
---
 dev-libs/gmime/gmime-2.6.20-r2.ebuild | 71 +++++++++++++++++++++++++++++++++++
 dev-libs/gmime/gmime-2.6.20-r3.ebuild | 70 ++++++++++++++++++++++++++++++++++
 dev-libs/gmime/metadata.xml           |  3 ++
 3 files changed, 144 insertions(+)
 create mode 100644 dev-libs/gmime/gmime-2.6.20-r2.ebuild
 create mode 100644 dev-libs/gmime/gmime-2.6.20-r3.ebuild

(limited to 'dev-libs')

diff --git a/dev-libs/gmime/gmime-2.6.20-r2.ebuild b/dev-libs/gmime/gmime-2.6.20-r2.ebuild
new file mode 100644
index 000000000000..bff36f5552ce
--- /dev/null
+++ b/dev-libs/gmime/gmime-2.6.20-r2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils mono-env gnome2 vala
+
+DESCRIPTION="Utilities for creating and parsing messages using MIME"
+HOMEPAGE="http://spruce.sourceforge.net/gmime/ https://developer.gnome.org/gmime/stable/"
+
+SLOT="2.6"
+LICENSE="LGPL-2.1"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="doc mono smime static-libs vala"
+
+RDEPEND="
+	>=dev-libs/glib-2.18:2
+	sys-libs/zlib
+	mono? (
+		dev-lang/mono
+		>=dev-dotnet/glib-sharp-2.4.0:2 )
+	smime? ( >=app-crypt/gpgme-1.1.6 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.8
+	virtual/pkgconfig
+	doc? ( app-text/docbook-sgml-utils )
+	mono? ( dev-dotnet/gtk-sharp-gapi:2 )
+	vala? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-1.30.0 )
+"
+
+pkg_setup() {
+	use mono && mono-env_pkg_setup
+}
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--enable-cryptography \
+		--disable-strict-parser \
+		$(use_enable mono) \
+		$(use_enable smime) \
+		$(use_enable static-libs static) \
+		$(use_enable vala)
+}
+
+src_compile() {
+	MONO_PATH="${S}" gnome2_src_compile
+	if use doc; then
+		emake -C docs/tutorial html
+	fi
+}
+
+src_install() {
+	GACUTIL_FLAGS="/root '${ED}/usr/$(get_libdir)' /gacdir '${EPREFIX}/usr/$(get_libdir)' /package ${PN}" \
+		gnome2_src_install
+
+	if use doc ; then
+		docinto tutorial
+		dodoc docs/tutorial/html/*
+	fi
+}
diff --git a/dev-libs/gmime/gmime-2.6.20-r3.ebuild b/dev-libs/gmime/gmime-2.6.20-r3.ebuild
new file mode 100644
index 000000000000..30439fdc7e13
--- /dev/null
+++ b/dev-libs/gmime/gmime-2.6.20-r3.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils mono-env gnome2 vala
+
+DESCRIPTION="Utilities for creating and parsing messages using MIME"
+HOMEPAGE="http://spruce.sourceforge.net/gmime/ https://developer.gnome.org/gmime/stable/"
+
+SLOT="2.6"
+LICENSE="LGPL-2.1"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="doc mono smime static-libs vala"
+
+RDEPEND="
+	>=dev-libs/glib-2.18:2
+	sys-libs/zlib
+	mono? (
+		dev-lang/mono
+		>=dev-dotnet/gtk-sharp-2.12.21:2 )
+	smime? ( >=app-crypt/gpgme-1.1.6 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.8
+	virtual/pkgconfig
+	doc? ( app-text/docbook-sgml-utils )
+	vala? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-1.30.0 )
+"
+
+pkg_setup() {
+	use mono && mono-env_pkg_setup
+}
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--enable-cryptography \
+		--disable-strict-parser \
+		$(use_enable mono) \
+		$(use_enable smime) \
+		$(use_enable static-libs static) \
+		$(use_enable vala)
+}
+
+src_compile() {
+	MONO_PATH="${S}" gnome2_src_compile
+	if use doc; then
+		emake -C docs/tutorial html
+	fi
+}
+
+src_install() {
+	GACUTIL_FLAGS="/root '${ED}/usr/$(get_libdir)' /gacdir '${EPREFIX}/usr/$(get_libdir)' /package ${PN}" \
+		gnome2_src_install
+
+	if use doc ; then
+		docinto tutorial
+		dodoc docs/tutorial/html/*
+	fi
+}
diff --git a/dev-libs/gmime/metadata.xml b/dev-libs/gmime/metadata.xml
index 24ed35a7bf95..3faea473b958 100644
--- a/dev-libs/gmime/metadata.xml
+++ b/dev-libs/gmime/metadata.xml
@@ -8,4 +8,7 @@
 	<upstream>
 		<remote-id type="sourceforge">spruce</remote-id>
 	</upstream>
+	<use>
+		<flag name="smime">Enable experimental S/MIME support</flag>
+	</use>
 </pkgmetadata>
-- 
cgit v1.2.3-65-gdbad