From e4810615f173a7d7e82fa3c78a5c3cd0ce4f9913 Mon Sep 17 00:00:00 2001
From: Alex Brandt <alunduil@gentoo.org>
Date: Sat, 22 Oct 2016 20:27:56 -0500
Subject: dev-python/aiohttp: add version 1.0.5

Package-Manager: portage-2.3.2
---
 dev-python/aiohttp/aiohttp-1.0.5.ebuild | 58 +++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-python/aiohttp/aiohttp-1.0.5.ebuild

(limited to 'dev-python/aiohttp/aiohttp-1.0.5.ebuild')

diff --git a/dev-python/aiohttp/aiohttp-1.0.5.ebuild b/dev-python/aiohttp/aiohttp-1.0.5.ebuild
new file mode 100644
index 000000000000..b6f53c2eba99
--- /dev/null
+++ b/dev-python/aiohttp/aiohttp-1.0.5.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+PYTHON_COMPAT=( python3_4 python3_5 )
+
+inherit distutils-r1 vcs-snapshot
+
+DESCRIPTION="http client/server for asyncio"
+HOMEPAGE="https://pypi.python.org/pypi/aiohttp"
+SRC_URI="https://github.com/KeepSafe/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+EGIT_REPO_URI="https://github.com/KeepSafe/aiohttp"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+CDEPEND="
+	dev-python/async_timeout[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	>=dev-python/multidict-2.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/alabaster-0.6.2[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-asyncio[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-newsfeed[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-spelling[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${CDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		www-servers/gunicorn[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	PYTHONPATH="${PWD}:${PYTHONPATH}" ${PYTHON} -m pytest tests/ || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad