From 5d29a05af8cb811f328638895c334e14df23c4ef Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sat, 8 Jan 2022 23:15:17 +0100
Subject: dev-python/build: New test-dep of setuptools, v0.7.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/build/Manifest           |  1 +
 dev-python/build/build-0.7.0.ebuild | 55 +++++++++++++++++++++++++++++++++++++
 dev-python/build/metadata.xml       | 12 ++++++++
 3 files changed, 68 insertions(+)
 create mode 100644 dev-python/build/Manifest
 create mode 100644 dev-python/build/build-0.7.0.ebuild
 create mode 100644 dev-python/build/metadata.xml

(limited to 'dev-python/build')

diff --git a/dev-python/build/Manifest b/dev-python/build/Manifest
new file mode 100644
index 000000000000..d31757b11156
--- /dev/null
+++ b/dev-python/build/Manifest
@@ -0,0 +1 @@
+DIST build-0.7.0.gh.tar.gz 37127 BLAKE2B b06ba16c154087046bd5efddb5fd6f60dad9ee79a204a0c1124fb4885d3692bcf4bd88b75c9665ade3f8457e12742d32e3cef40a0ffb5a894b049a6e942c09e3 SHA512 fd8410dc91333ba94c5141dd78f8052b66f947839752a5d0f401630f6bceed5be2e1f45eceaa2a98908c0e3ddb88a00e3ccca341a3890fa99202bc560ab6ff42
diff --git a/dev-python/build/build-0.7.0.ebuild b/dev-python/build/build-0.7.0.ebuild
new file mode 100644
index 000000000000..ec8c17465fa4
--- /dev/null
+++ b/dev-python/build/build-0.7.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="A simple, correct PEP517 package builder"
+HOMEPAGE="
+	https://pypi.org/project/build/
+	https://github.com/pypa/build/"
+SRC_URI="
+	https://github.com/pypa/build/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/packaging-19.0[${PYTHON_USEDEP}]
+	>=dev-python/pep517-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.0.0[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		>=dev-python/filelock-3[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-rerunfailures-9.1[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		>=dev-python/setuptools-56.0.0[${PYTHON_USEDEP}]
+		>=dev-python/wheel-0.36.0[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken by the presence of flit_core
+		tests/test_util.py::test_wheel_metadata_isolation
+		# broken by the presence of virtualenv (it changes the error
+		# messages, sic!)
+		tests/test_env.py::test_isolated_env_log
+		tests/test_main.py::test_output_env_subprocess_error
+		'tests/test_main.py::test_output[via-sdist-isolation]'
+		'tests/test_main.py::test_output[wheel-direct-isolation]'
+		# Internet
+		tests/test_main.py::test_build_package
+		tests/test_main.py::test_build_package_via_sdist
+		'tests/test_util.py::test_wheel_metadata[True]'
+		tests/test_util.py::test_with_get_requires
+	)
+
+	epytest -p no:flaky \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/build/metadata.xml b/dev-python/build/metadata.xml
new file mode 100644
index 000000000000..dfa7f7dccb22
--- /dev/null
+++ b/dev-python/build/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">build</remote-id>
+		<remote-id type="github">pypa/build</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3-65-gdbad