From fab36a01dbdbeb4c8d5085a4aecc68a0587447c4 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sat, 30 May 2020 09:05:10 +0200
Subject: dev-python/mako: Bump to 1.1.3
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/mako/mako-1.1.3.ebuild | 53 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-python/mako/mako-1.1.3.ebuild

(limited to 'dev-python/mako/mako-1.1.3.ebuild')

diff --git a/dev-python/mako/mako-1.1.3.ebuild b/dev-python/mako/mako-1.1.3.ebuild
new file mode 100644
index 000000000000..41ee455ad58f
--- /dev/null
+++ b/dev-python/mako/mako-1.1.3.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( pypy3 python{2_7,3_{6,7,8,9}} )
+
+inherit distutils-r1 eutils
+
+MY_P=${P^}
+DESCRIPTION="A Python templating language"
+HOMEPAGE="https://www.makotemplates.org/ https://pypi.org/project/Mako/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${PN^}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc"
+
+RDEPEND=">=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' -2)
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/mako-1.1.1-pypy3-test.patch
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# seriously?
+	sed -i -e 's:from nose import:from unittest import:' \
+		test/__init__.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_install_all() {
+	rm -r doc/build || die
+
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "Optional dependencies:"
+	optfeature "caching support" dev-python/beaker
+}
-- 
cgit v1.2.3-65-gdbad