From f0a84b3c0ae63c9e8927666db95b020fa16e1b9e Mon Sep 17 00:00:00 2001
From: Andrew Ammerlaan <andrewammerlaan@riseup.net>
Date: Sat, 10 Apr 2021 15:46:09 +0200
Subject: dev-python/mkdocs: allow use of lunr-0.5.9, add py3.9

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@riseup.net>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 dev-python/mkdocs/mkdocs-1.1.2-r1.ebuild | 67 ++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 dev-python/mkdocs/mkdocs-1.1.2-r1.ebuild

(limited to 'dev-python/mkdocs/mkdocs-1.1.2-r1.ebuild')

diff --git a/dev-python/mkdocs/mkdocs-1.1.2-r1.ebuild b/dev-python/mkdocs/mkdocs-1.1.2-r1.ebuild
new file mode 100644
index 000000000000..6d18515e6d89
--- /dev/null
+++ b/dev-python/mkdocs/mkdocs-1.1.2-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Project documentation with Markdown"
+HOMEPAGE="https://www.mkdocs.org https://github.com/mkdocs/mkdocs"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="doc"
+
+BDEPEND="
+	doc? (
+		dev-python/mdx_gh_links
+	)
+"
+
+RDEPEND="
+	>=dev-python/click-7.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.3[${PYTHON_USEDEP}]
+	>=dev-python/livereload-2.6.1[${PYTHON_USEDEP}]
+	~dev-python/lunr-0.5.9[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.2.1[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.2[${PYTHON_USEDEP}]
+	>=www-servers/tornado-5.1.1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# Tests fails if additional themes are installed
+	sed -i -e 's:test_get_themes:_&:' \
+		mkdocs/tests/utils/utils_tests.py || die
+
+	# Upstream pins this to workaround with a bug
+	# in lunr, from 0.5.9 onwards lunr (mistakenly?)
+	# depends on nltk<3.5 if [languages], which does not
+	# work with mkdocs. We remove the [languages] part, and
+	# allow the use of 0.5.9 instead of 0.5.8.
+	# Tests pass.
+	sed -i -e 's/lunr\[languages\]==0.5.8/lunr==0.5.9/g' \
+		setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	default
+	if use doc; then
+		# cannot just do mkdocs build, because that fails if
+		# the package isn't already installed
+		python -m mkdocs build || die "Failed to make docs"
+		# Colliding files found by ecompress:
+		rm site/sitemap.xml.gz || die
+		HTML_DOCS=( "site/." )
+	fi
+}
-- 
cgit v1.2.3-18-g5258