From 5b40d61944753213146c034c3f4b93d13775404e Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Fri, 16 Oct 2020 17:26:03 +0200
Subject: dev-python/pyglet: Bump to 1.5.8
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pyglet/Manifest            |  1 +
 dev-python/pyglet/pyglet-1.5.8.ebuild | 62 +++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)
 create mode 100644 dev-python/pyglet/pyglet-1.5.8.ebuild

(limited to 'dev-python/pyglet')

diff --git a/dev-python/pyglet/Manifest b/dev-python/pyglet/Manifest
index 22553e3c7142..9418add7c98d 100644
--- a/dev-python/pyglet/Manifest
+++ b/dev-python/pyglet/Manifest
@@ -1,2 +1,3 @@
 DIST pyglet-1.5.3.tar.gz 6356079 BLAKE2B 517b196eff334d572d4db181ce0480c3af8e2bc4a92e23e1fd7c335aedebe3afa493eb3f4745d8daffc3c7d930b9e333075014d2ba5d4303f4691c490a09f252 SHA512 12e7189272b9ab3b4bd3d713d0e979cfc1d76200fc8454b31573fca29b179f99242c34a1adb7a1c2fabb7b950cc3006cfcd8b188eb2c50ae95cca95b0e15582c
 DIST pyglet-1.5.7.tar.gz 6367378 BLAKE2B 68d4aa673a7463f7da0f4ccb7f413b602f32ecc423438326fc4262a4449fe22dff25a513074611ce2c77c130dfe9cc29e44e54a95169875208731f70803f1a45 SHA512 2c2a06636b1db788241028d1ef2290a774b98721ccc92ceed2b2895bcee81d4aa72b2111896091b54531936513772505b0d43003e412735d606130ed4b08f8c9
+DIST pyglet-1.5.8.tar.gz 6394207 BLAKE2B dcd3750b7296ab919ecb20417f0dfa2e89ab2754c28562a38175cf87f06bcd41d9b1ed2c568ed516e444a5968e21a772f0f4cfb5b626bb1aeb066f3b17f1cf18 SHA512 346dafbc751a4cfbdaf65643701500f5b5ad40541168eeea13467d0b97283baa35b22708dfc15569adcfad0b8ecb51d1b45d18775d564b12ed4be0965971229b
diff --git a/dev-python/pyglet/pyglet-1.5.8.ebuild b/dev-python/pyglet/pyglet-1.5.8.ebuild
new file mode 100644
index 000000000000..13aa03ae4b4a
--- /dev/null
+++ b/dev-python/pyglet/pyglet-1.5.8.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="Cross-platform windowing and multimedia library for Python"
+HOMEPAGE="http://www.pyglet.org/"
+SRC_URI="https://github.com/pyglet/pyglet/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples image +sound"
+
+BDEPEND="
+	test? (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/gst-python[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	virtual/glu
+	virtual/opengl
+	image? ( || (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		x11-libs/gtk+:2
+	) )
+	sound? ( || (
+		media-libs/openal
+		media-sound/pulseaudio
+	) )
+"
+#	ffmpeg? ( media-libs/avbin-bin )
+
+DOCS=( DESIGN NOTICE README.md RELEASE_NOTES )
+
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	xdg_environment_reset
+
+	# Specify path to avoid running interactive tests
+	# We could add in integration tests, but they're slow
+	pytest -vv tests/unit || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad