From cb39e50eab7ebf73c2fec2aa3bb5b728354034a7 Mon Sep 17 00:00:00 2001
From: Arthur Zamarin <arthurzam@gentoo.org>
Date: Wed, 22 Sep 2021 16:29:35 +0300
Subject: dev-python/zope-configuration: enable py3.10, enable tests

Closes: https://bugs.gentoo.org/798618
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
---
 .../zope-configuration-4.4.0-r1.ebuild             | 45 ++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 dev-python/zope-configuration/zope-configuration-4.4.0-r1.ebuild

(limited to 'dev-python/zope-configuration')

diff --git a/dev-python/zope-configuration/zope-configuration-4.4.0-r1.ebuild b/dev-python/zope-configuration/zope-configuration-4.4.0-r1.ebuild
new file mode 100644
index 000000000000..843acb2a6151
--- /dev/null
+++ b/dev-python/zope-configuration/zope-configuration-4.4.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Zope Configuration Architecture"
+HOMEPAGE="https://github.com/zopefoundation/zope.configuration
+	https://docs.zope.org/zope.configuration/"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="dev-python/zope-i18nmessageid[${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+	>=dev-python/zope-schema-4.9[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/manuel[${PYTHON_USEDEP}]
+		dev-python/zope-testing[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	eunittest src
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# remove .pth files since dev-python/namespace-zope handles the ns
+	find "${D}" -name '*.pth' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad