From 72e5f9227f81108f9f6714631e19c85ac39b74ee Mon Sep 17 00:00:00 2001
From: Hans de Graaff <graaff@gentoo.org>
Date: Wed, 27 Jul 2016 07:19:04 +0200
Subject: dev-ruby/listen: add 3.1.5

Drop arm, ppc64 keywords due to new dependency on
dev-ruby/ruby_dep, bug 589798

Package-Manager: portage-2.2.28
---
 dev-ruby/listen/listen-3.1.5.ebuild | 48 +++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-ruby/listen/listen-3.1.5.ebuild

(limited to 'dev-ruby/listen/listen-3.1.5.ebuild')

diff --git a/dev-ruby/listen/listen-3.1.5.ebuild b/dev-ruby/listen/listen-3.1.5.ebuild
new file mode 100644
index 000000000000..0e2a7c90e242
--- /dev/null
+++ b/dev-ruby/listen/listen-3.1.5.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+USE_RUBY="ruby20 ruby21 ruby22 ruby23"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+SRC_URI="https://github.com/guard/listen/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+DESCRIPTION="Listens to file modifications and notifies you about the changes"
+HOMEPAGE="https://github.com/guard/listen"
+
+LICENSE="MIT"
+SLOT="3"
+KEYWORDS="~amd64"
+IUSE="test"
+
+# Block on other packages trying to install a /usr/bin/listen
+RDEPEND+="!!media-sound/listen !!media-radio/ax25 !!<dev-ruby/listen-2.8.6-r1:2"
+
+ruby_add_rdepend ">=dev-ruby/rb-inotify-0.9.7 >=dev-ruby/ruby_dep-1.2:1"
+
+ruby_add_bdepend "test? ( dev-ruby/thor )"
+
+all_ruby_prepare() {
+	rm -f Gemfile || die
+	sed -i -e "/git/,+3d" -e "/rb-fsevent/d" ${PN}.gemspec || die
+	sed -i -e "/rb-fsevent/d"  lib/listen/adapter/darwin.rb || die
+	rm -rf spec/lib/listen/adapter/darwin_spec.rb || die
+}
+
+each_ruby_prepare() {
+	mkdir spec/.fixtures || die
+}
+
+each_ruby_test() {
+	RSPEC_VERSION=3 ruby-ng_rspec
+	rm -rf spec/.fixtures || die
+}
-- 
cgit v1.2.3