From 9adbd76fe7f48d8c0cd713dd3cbf13620cb07473 Mon Sep 17 00:00:00 2001
From: Hans de Graaff <graaff@gentoo.org>
Date: Mon, 25 Jun 2018 20:43:09 +0200
Subject: dev-ruby/i18n: add ruby25

Package-Manager: Portage-2.3.40, Repoman-2.3.9
---
 dev-ruby/i18n/i18n-1.0.1-r1.ebuild | 59 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-ruby/i18n/i18n-1.0.1-r1.ebuild

(limited to 'dev-ruby')

diff --git a/dev-ruby/i18n/i18n-1.0.1-r1.ebuild b/dev-ruby/i18n/i18n-1.0.1-r1.ebuild
new file mode 100644
index 000000000000..4b4f9e363e13
--- /dev/null
+++ b/dev-ruby/i18n/i18n-1.0.1-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_RECIPE_TEST="test"
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem versionator
+
+DESCRIPTION="Add Internationalization support to your Ruby application"
+HOMEPAGE="http://rails-i18n.org/"
+SRC_URI="https://github.com/svenfuchs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="$(get_version_component_range 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+ruby_add_rdepend "dev-ruby/concurrent-ruby:1"
+
+ruby_add_bdepend "test? (
+	>=dev-ruby/activesupport-4.2
+	dev-ruby/bundler
+	>=dev-ruby/mocha-0.13
+	dev-ruby/test_declarative )"
+
+all_ruby_prepare() {
+	rm -f gemfiles/*.lock || die
+
+	# Remove optional unpackaged oj gem
+	sed -i -e '/oj/ s:^:#:' gemfiles/* || die
+}
+
+each_ruby_test() {
+	case ${RUBY} in
+		*ruby25)
+			versions="5.1"
+			;;
+		*ruby22|*ruby23|*ruby24)
+			versions="4.2 5.0 5.1"
+			;;
+		*)
+			versions="4.2"
+			;;
+	esac
+
+	for version in ${versions} ; do
+		if has_version "dev-ruby/activesupport:${version}" ; then
+			einfo "Running tests with activesupport ${version}"
+			BUNDLE_GEMFILE="${S}/gemfiles/Gemfile.rails-${version}.x" ${RUBY} -S bundle exec ${RUBY} -S rake test || die
+		fi
+	done
+}
-- 
cgit v1.2.3-65-gdbad