From 78e2841592e3e12ee13f0920d2237b8c0a22fda0 Mon Sep 17 00:00:00 2001
From: Alexis Ballier <aballier@gentoo.org>
Date: Sun, 30 Jul 2017 18:38:02 +0200
Subject: dev-util/rosdep: bump to 0.11.6

Package-Manager: Portage-2.3.6, Repoman-2.3.3
---
 dev-util/rosdep/Manifest             |  1 +
 dev-util/rosdep/rosdep-0.11.6.ebuild | 60 ++++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)
 create mode 100644 dev-util/rosdep/rosdep-0.11.6.ebuild

(limited to 'dev-util/rosdep')

diff --git a/dev-util/rosdep/Manifest b/dev-util/rosdep/Manifest
index 0315eea08733..5fc0f28b26ea 100644
--- a/dev-util/rosdep/Manifest
+++ b/dev-util/rosdep/Manifest
@@ -1 +1,2 @@
 DIST rosdep-0.11.5.tar.gz 76136 SHA256 46e072074270a1ea25411829814f4bdc1f34b358c950e9b8a7b75b4a40efd96a SHA512 593ca209714945e79ec878e0e84d086645bea9095bc2fbf0a3ac48b8696c8694990f554f160b8271734e2980d95390dc2dffbd3da765c43c505d8b2e1e05e381 WHIRLPOOL 59b04fbfa5521a8df7c9d556bc7faf0da3d425a56d6dfeafb8583bf24a24f6c762dac7e9f1abb747fa7604c9cb1c621c13537a7eb2dcf88408b50a183ac85da9
+DIST rosdep-0.11.6.tar.gz 79121 SHA256 d30b46fe89832fd47e03f74f0d720d94793875aa02ee9e86f403195fb66c9218 SHA512 f662ab62951d84db1af48978791304e0c1800929a1ae89c360a042a17bc48c2ff6b7ea790fa7fc16852fb5f09f62e9b800d7be7f71ee18124102e48f030e3b2a WHIRLPOOL 7111e702777e9fb5ca3d2c9a716def34f6dd985cf7523b49b150d140622aeb18487bf0ded727add2a43d88deb226568df8e6bea61e8c5e4e0e8d777d61c102dd
diff --git a/dev-util/rosdep/rosdep-0.11.6.ebuild b/dev-util/rosdep/rosdep-0.11.6.ebuild
new file mode 100644
index 000000000000..463cc83cafbd
--- /dev/null
+++ b/dev-util/rosdep/rosdep-0.11.6.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} pypy{,3} )
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/ros-infrastructure/rosdep"
+fi
+
+inherit ${SCM} distutils-r1
+
+DESCRIPTION="Command-line tool for installing ROS system dependencies"
+HOMEPAGE="http://wiki.ros.org/rosdep"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="http://download.ros.org/downloads/${PN}/${P}.tar.gz
+		https://github.com/ros-infrastructure/rosdep/archive/${PV}.tar.gz -> ${P}.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="test"
+
+RDEPEND="
+	dev-python/catkin_pkg[${PYTHON_USEDEP}]
+	dev-python/rospkg[${PYTHON_USEDEP}]
+	dev-python/rosdistro[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/nose[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	nosetests --with-coverage --cover-package=rosdep2 --with-xunit test || die
+}
+
+pkg_postrm() {
+	if [ "${ROOT:-/}" = "/" ] ; then
+		einfo "Removing rosdep default sources list."
+		rm -f "${EPREFIX}/etc/ros/rosdep/sources.list.d/20-default.list"
+	fi
+}
+
+pkg_postinst() {
+	if [ "${ROOT:-/}" = "/" -a ! -f "${EPREFIX}/etc/ros/rosdep/sources.list.d/20-default.list" ] ; then
+		einfo "Initializing rosdep"
+		rosdep init
+	fi
+}
-- 
cgit v1.2.3-65-gdbad