From 2fd89caae1de99c85d231744281eec1cb4069d2b Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Tue, 11 Aug 2020 11:39:48 +0200
Subject: dev-util/sysdig: Bump to 0.27.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-util/sysdig/Manifest             |  1 +
 dev-util/sysdig/sysdig-0.27.0.ebuild | 69 ++++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)
 create mode 100644 dev-util/sysdig/sysdig-0.27.0.ebuild

(limited to 'dev-util/sysdig')

diff --git a/dev-util/sysdig/Manifest b/dev-util/sysdig/Manifest
index e7e363175fd3..056a17b1dd92 100644
--- a/dev-util/sysdig/Manifest
+++ b/dev-util/sysdig/Manifest
@@ -1,2 +1,3 @@
 DIST sysdig-0.26.6.tar.gz 923918 BLAKE2B e022eba30977f5300c80a4806926d3e755b1395f05475c1fe925b86823670e397ad29e8bd18b1beaa893cb1bf83c329960c1bf9ff6faf0a5144343e88d52a4a0 SHA512 94784f0dfe46924b81d8804d950a9563cd18f4aa8b1cacd7e27e3974ecf7215223e03bdab001f408f64eb6c72f0da5082fd922d63079119427eb493c77e15795
 DIST sysdig-0.26.7.tar.gz 924647 BLAKE2B 31973410e8e166d82c3851eceee8bdcd808db8181e8330841ff746a2d2c35936fda9dcf23c16697e37da339a647b534b17d0c1bb58c547621f2a3f926fca5016 SHA512 37f3544b1994c8c9048c6ff886da0c2ea6cbfe0a1cedb930b2a06bb85fa9da80a8197409a99b95245dec9ca1957a0f1fe989f688a549739d71ff778087d20b76
+DIST sysdig-0.27.0.tar.gz 933094 BLAKE2B e412bd2a35a62b580344a49e2deee85764710f91327cd63b42913dc361ee96943ffe51b90ee745c420454f0a4be455606d486a91ab3e103d7e396f04dc3f1ff4 SHA512 102150cc641165a6c18ce71e3c6148dc10700f614fec7e1909c29172e3cce02dfa16af56aabdcd420499d0aa89f90fee8f26d92a250b0a521d1b9d416c6a678f
diff --git a/dev-util/sysdig/sysdig-0.27.0.ebuild b/dev-util/sysdig/sysdig-0.27.0.ebuild
new file mode 100644
index 000000000000..55a20f694f42
--- /dev/null
+++ b/dev-util/sysdig/sysdig-0.27.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1 cmake
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="https://sysdig.com/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl +modules test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-misc/jq:0=
+	dev-cpp/tbb:0=
+	dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	dev-libs/libb64:0=
+	dev-libs/protobuf:0=
+	net-dns/c-ares:0=
+	net-libs/grpc:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0=
+	libressl? ( dev-libs/libressl:0= )
+	!libressl? ( dev-libs/openssl:0= )
+	net-misc/curl:0="
+DEPEND="${RDEPEND}
+	virtual/os-headers
+	test? ( dev-cpp/gtest )"
+PDEPEND="
+	modules? ( >=dev-util/sysdig-kmod-${PV} )"
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCREATE_TEST_TARGETS=$(usex test)
+
+		# done in dev-util/sysdig-kmod
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_DEPS=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# remove sources
+	rm -r "${ED}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED}"/usr/etc || die
+}
-- 
cgit v1.2.3-65-gdbad