From b251d6cac56f1d2a38189c4e8347dfe419388daf Mon Sep 17 00:00:00 2001
From: Ionen Wolkens <ionen@gentoo.org>
Date: Sat, 19 Jun 2021 22:28:20 -0400
Subject: games-action/heroes: fix RequiredUseDefaults, tighten sdl deps

Cleaned up variables given unlikely changing those will
ever be needed with last release being in 2002.

Also add a generic .desktop file, and einstalldocs.

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
---
 games-action/heroes/heroes-0.21-r2.ebuild | 74 -----------------------------
 games-action/heroes/heroes-0.21-r3.ebuild | 78 +++++++++++++++++++++++++++++++
 2 files changed, 78 insertions(+), 74 deletions(-)
 delete mode 100644 games-action/heroes/heroes-0.21-r2.ebuild
 create mode 100644 games-action/heroes/heroes-0.21-r3.ebuild

(limited to 'games-action')

diff --git a/games-action/heroes/heroes-0.21-r2.ebuild b/games-action/heroes/heroes-0.21-r2.ebuild
deleted file mode 100644
index a576ebf8f758..000000000000
--- a/games-action/heroes/heroes-0.21-r2.ebuild
+++ /dev/null
@@ -1,74 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools
-
-data_ver=1.5
-snd_trk_ver=1.0
-snd_eff_ver=1.0
-
-DESCRIPTION="Heroes Enjoy Riding Over Empty Slabs: similar to Tron and Nibbles"
-HOMEPAGE="http://heroes.sourceforge.net/"
-SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
-	mirror://sourceforge/${PN}/${PN}-data-${data_ver}.tar.bz2
-	mirror://sourceforge/${PN}/${PN}-sound-tracks-${snd_trk_ver}.tar.bz2
-	mirror://sourceforge/${PN}/${PN}-sound-effects-${snd_eff_ver}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="ggi nls sdl"
-REQUIRED_USE="^^ ( ggi sdl )"
-RESTRICT="test"
-
-RDEPEND="
-	ggi? (
-		media-libs/libggi
-		media-libs/libgii
-		media-libs/libmikmod
-	)
-	nls? ( virtual/libintl )
-	sdl? (
-		media-libs/libsdl
-		media-libs/sdl-mixer
-	)"
-DEPEND="${RDEPEND}"
-BDEPEND="nls? ( sys-devel/gettext )"
-
-PATCHES=(
-	"${FILESDIR}"/${P}-autotools.patch
-	"${FILESDIR}"/${P}-gcc4.patch
-	"${FILESDIR}"/${P}-cvs-segfault-fix.patch
-	"${FILESDIR}"/${P}-compilation.patch
-	"${FILESDIR}"/${P}-gcc10.patch
-)
-
-src_prepare() {
-	default
-	eautoreconf
-}
-
-src_configure() {
-	local pkg
-	for pkg in ${A//.tar.bz2}; do
-		cd "${WORKDIR}"/${pkg} || die
-		econf \
-			--disable-heroes-debug \
-			--disable-optimizations \
-			$(use_with sdl) \
-			$(use_with sdl sdl-mixer) \
-			$(use_with ggi) \
-			$(use_with ggi mikmod) \
-			$(use_enable nls)
-	done
-}
-
-src_install() {
-	local pkg
-	for pkg in ${A//.tar.bz2} ; do
-		cd "${WORKDIR}"/${pkg} || die
-		emake DESTDIR="${D}" install
-	done
-}
diff --git a/games-action/heroes/heroes-0.21-r3.ebuild b/games-action/heroes/heroes-0.21-r3.ebuild
new file mode 100644
index 000000000000..502043e2eb33
--- /dev/null
+++ b/games-action/heroes/heroes-0.21-r3.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop
+
+DESCRIPTION="Heroes Enjoy Riding Over Empty Slabs: similar to Tron and Nibbles"
+HOMEPAGE="http://heroes.sourceforge.net/"
+SRC_URI="
+	mirror://sourceforge/${PN}/${P}.tar.bz2
+	mirror://sourceforge/${PN}/${PN}-data-1.5.tar.bz2
+	mirror://sourceforge/${PN}/${PN}-sound-tracks-1.0.tar.bz2
+	mirror://sourceforge/${PN}/${PN}-sound-effects-1.0.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ggi nls +sdl"
+REQUIRED_USE="^^ ( ggi sdl )"
+RESTRICT="test"
+
+RDEPEND="
+	ggi? (
+		media-libs/libggi
+		media-libs/libgii
+		media-libs/libmikmod
+	)
+	nls? ( virtual/libintl )
+	sdl? (
+		media-libs/libsdl[joystick,sound,video]
+		media-libs/sdl-mixer[mod]
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-autotools.patch
+	"${FILESDIR}"/${P}-gcc4.patch
+	"${FILESDIR}"/${P}-cvs-segfault-fix.patch
+	"${FILESDIR}"/${P}-compilation.patch
+	"${FILESDIR}"/${P}-gcc10.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local econfargs=(
+		$(use_enable nls)
+		$(use_with ggi mikmod)
+		$(use_with ggi)
+		$(use_with sdl sdl-mixer)
+		$(use_with sdl)
+		--disable-heroes-debug
+		--disable-optimizations
+	)
+
+	local pkg
+	for pkg in ${A//.tar.bz2}; do
+		cd "${WORKDIR}"/${pkg} || die
+		econf "${econfargs[@]}"
+	done
+}
+
+src_install() {
+	local pkg
+	for pkg in ${A//.tar.bz2} ; do
+		emake -C "${WORKDIR}"/${pkg} DESTDIR="${D}" install
+	done
+
+	einstalldocs
+
+	make_desktop_entry ${PN} Heroes applications-games
+}
-- 
cgit v1.2.3-65-gdbad