From db614687046a96fd4a23c66b9bd3e661aea093c0 Mon Sep 17 00:00:00 2001
From: Andreas Zuber <a.zuber@gmx.ch>
Date: Tue, 13 Oct 2020 23:02:10 +0200
Subject: games-util/pyfa: version bump to 2.29.0

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Andreas Zuber <a.zuber@gmx.ch>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 games-util/pyfa/Manifest           |  1 +
 games-util/pyfa/pyfa-2.29.0.ebuild | 92 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 93 insertions(+)
 create mode 100644 games-util/pyfa/pyfa-2.29.0.ebuild

(limited to 'games-util')

diff --git a/games-util/pyfa/Manifest b/games-util/pyfa/Manifest
index 63e866497544..409b47abd405 100644
--- a/games-util/pyfa/Manifest
+++ b/games-util/pyfa/Manifest
@@ -1,2 +1,3 @@
 DIST pyfa-2.24.1.tar.gz 12648921 BLAKE2B 5715d81144df32cad83eb21d7f8800eb9773139e9305402a5096c585362fcabd0d705529a8887a8c8092637b8348d2a7e8a77e1f6eb362fd83ea39a86203ccb4 SHA512 ffe8a6e9c9c9b593516d9ba76ccb9e69788124132de642f45f5527468645d46f75e4c2388bb5f01788eb85f3e535ade110cfffc92c2943d96f477b5652528328
 DIST pyfa-2.28.3.tar.gz 12685191 BLAKE2B b73663479e39f8948de0ad0de3edb3a89b65bb5b6640332e8fed39f33b222fbc0f4b47487112b01895413fa751ee8dabcde2083a3f3a6b90fe0ad72b24165434 SHA512 7e432658eedb8dfbc9cd41d3ab7da3bf1d411e6935ad56434af1551eeae4de803f3d5447bff4fd5d569d20f1f3eca9acaa1ac22c163bec1ac7720807643b4187
+DIST pyfa-2.29.0.tar.gz 12631717 BLAKE2B 5999c82f090d36355188601158c648112b5d194066b193080260d609e3edbecba4078d9a02ebdfaa6561f555e3876833b20f81b0992e95f4efd0dc632563c95f SHA512 2d7945c7d93a358ab06de554bd6a7f359934a8508cb828d5a4c4c47e743217560083ed16dc91e8c7f0f14f7aec96ec2c7965bae51b687a8e63558365628c0d43
diff --git a/games-util/pyfa/pyfa-2.29.0.ebuild b/games-util/pyfa/pyfa-2.29.0.ebuild
new file mode 100644
index 000000000000..50ffcdd37c25
--- /dev/null
+++ b/games-util/pyfa/pyfa-2.29.0.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="sqlite"
+
+inherit desktop edos2unix python-single-r1 xdg
+
+DESCRIPTION="Python Fitting Assistant - a ship fitting application for EVE Online"
+HOMEPAGE="https://github.com/pyfa-org/Pyfa"
+
+LICENSE="GPL-3+ all-rights-reserved"
+SLOT="0"
+if [[ ${PV} = 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/pyfa-org/Pyfa.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/pyfa-org/Pyfa/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/Pyfa-${PV}"
+fi
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="mirror bindist"
+
+DEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/cryptography-2.3[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/logbook-1.0.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pyyaml-5.1[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/sqlalchemy-1.3.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/wxpython-4.0.6[webkit,${PYTHON_MULTI_USEDEP}]
+	')
+	${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		>=dev-python/beautifulsoup-4.6.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/markdown2-2.3.5[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/packaging-16.8[${PYTHON_MULTI_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/requests-2.0.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/roman-2.0.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/matplotlib-3.1.2[wxwidgets,${PYTHON_MULTI_USEDEP}]
+	')"
+BDEPEND="app-arch/zip"
+
+PATCHES=(
+	# fix import path in the main script for systemwide installation
+	"${FILESDIR}/${PN}-2.9.3-import-pyfa.patch"
+)
+
+src_prepare() {
+	# get rid of CRLF line endings introduced in 1.1.10 so patches work
+	edos2unix config.py pyfa.py gui/bitmap_loader.py service/settings.py
+
+	default
+
+	# make python recognize pyfa as a package
+	touch __init__.py || die
+
+	sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
+		-e "s:%%EPREFIX%%:${EPREFIX}:" \
+		"${FILESDIR}/configforced-1.15.1.py" > configforced.py || die
+	sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
+		pyfa.py > pyfa || die
+}
+
+src_install() {
+	python_moduleinto ${PN}
+	python_domodule eos gui service utils graphs
+	python_domodule config*.py __init__.py version.yml configforced.py db_update.py
+	python_doscript pyfa
+
+	insinto /usr/share/${PN}
+
+	einfo "Creating database ..."
+	${EPYTHON} ./db_update.py || die
+	doins eve.db
+
+	einfo "Compressing images ..."
+	pushd imgs > /dev/null || die
+	zip -r imgs.zip * || die "zip failed"
+	doins imgs.zip
+	popd > /dev/null || die
+
+	dodoc README.md
+	doicon -s 32 imgs/gui/pyfa.png
+	newicon -s 64 imgs/gui/pyfa64.png pyfa.png
+	domenu "${FILESDIR}/${PN}.desktop"
+}
-- 
cgit v1.2.3-65-gdbad