From c71c5a9e2dd183f06c779843b5f66e8dc67e69f6 Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Sat, 5 Feb 2022 13:13:21 -0800
Subject: gnome-extra/gnome-commander: Version bump to 1.14.0

Bug: https://bugs.gentoo.org/751001
Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 gnome-extra/gnome-commander/Manifest               |  1 +
 .../gnome-commander/gnome-commander-1.14.0.ebuild  | 54 ++++++++++++++++++++++
 2 files changed, 55 insertions(+)
 create mode 100644 gnome-extra/gnome-commander/gnome-commander-1.14.0.ebuild

(limited to 'gnome-extra')

diff --git a/gnome-extra/gnome-commander/Manifest b/gnome-extra/gnome-commander/Manifest
index 8f858312959e..22d8781ef4d2 100644
--- a/gnome-extra/gnome-commander/Manifest
+++ b/gnome-extra/gnome-commander/Manifest
@@ -1 +1,2 @@
 DIST gnome-commander-1.12.3.1.tar.xz 7530232 BLAKE2B 34a4cabafab52ab6f94619dafac4db87c12909eef22c13d50356dad925f129da182348eabd8993f69ffc398db163f81ec59c9a102530a9b49f7714b5d7c6db68 SHA512 1206d545493deeb2237af6b9026baf6faab2a8f6ae86eb1abb5c2e5ceb6212ad66382d3abd07c89f14271ac8709d14548f0bfe68fb0e11b1779e0c061e0272e5
+DIST gnome-commander-1.14.0.tar.xz 6909816 BLAKE2B fa7b3fc2696ec6520a5d2473d8728ceb16efb33134628e00a7b82f3656088a61247e5b2eeb7f3fb306866c9c1a454dbe4bb49af3a8217a1f2be6b951d7851fd2 SHA512 769f1272331ed71f558b87a73a920b9bfd5a2ea2af66972bdcac44d7a7623a6cb32460b0b650bd26d07c27bdc8b71c7d8bc2038076778aa356b638c4765ce4a5
diff --git a/gnome-extra/gnome-commander/gnome-commander-1.14.0.ebuild b/gnome-extra/gnome-commander/gnome-commander-1.14.0.ebuild
new file mode 100644
index 000000000000..f28df23d9ea4
--- /dev/null
+++ b/gnome-extra/gnome-commander/gnome-commander-1.14.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome2 optfeature
+
+DESCRIPTION="A graphical, full featured, twin-panel file manager"
+HOMEPAGE="https://gcmd.github.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="exif gsf pdf samba taglib test +unique"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.70.0:2
+	>=x11-libs/gtk+-2.24.0:2
+	unique? ( >=dev-libs/libunique-0.9.3:1 )
+	exif? ( >=media-gfx/exiv2-0.14 )
+	taglib? ( >=media-libs/taglib-1.4 )
+	gsf? ( >=gnome-extra/libgsf-1.12:= )
+	pdf? ( >=app-text/poppler-0.18 )
+"
+DEPEND="
+	${RDEPEND}
+	test? ( >=dev-cpp/gtest-1.7.0 )
+"
+BDEPEND="
+	app-text/yelp-tools
+	>=sys-devel/flex-2.0.0
+	dev-util/gtk-doc-am
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--without-libchm \
+		$(use_with exif exiv2) \
+		$(use_with gsf libgsf) \
+		$(use_with pdf poppler) \
+		$(use_with samba) \
+		$(use_with taglib) \
+		$(use_with unique)
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	optfeature "synchronizing files and directories" dev-util/meld
+	optfeature "viewing the documentation" gnome-extra/yelp
+}
-- 
cgit v1.2.3-65-gdbad