From bec1b273ff1411e50b15dca9447bfddf50556d1d Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Sat, 14 Mar 2020 14:53:13 +0200
Subject: gui-libs/libhandy: bump to 0.0.13

Closes: https://bugs.gentoo.org/708604
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 gui-libs/libhandy/Manifest               |  1 +
 gui-libs/libhandy/libhandy-0.0.13.ebuild | 61 ++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100644 gui-libs/libhandy/libhandy-0.0.13.ebuild

(limited to 'gui-libs')

diff --git a/gui-libs/libhandy/Manifest b/gui-libs/libhandy/Manifest
index e5c93a20fa45..cb2afb93485c 100644
--- a/gui-libs/libhandy/Manifest
+++ b/gui-libs/libhandy/Manifest
@@ -1 +1,2 @@
+DIST libhandy-v0.0.13.tar.bz2 394811 BLAKE2B 318c226f20b4d8032e984dbd47b4634e828b922dcbc244e4f3f35b94c38f27ed38427196d553809bb1d6bfa7c4830db5d27701e3595cac8a05b58a27ba4a2472 SHA512 a0918c55c9ac14af223a83db542e7dc815d97c844d1f0830a1bee4bdcdf248d00d049fa90fd2be96265535a68d56de5143ddd9264b5e997a902ac9558d5096f3
 DIST libhandy-v0.0.9.tar.bz2 110100 BLAKE2B c1abf60b37d76a0b2f0ed82152decc9a87c9feff664af8df91ede192018a70003ac7ff3c1307668e7196089f59bb5dc21d1449ccc1deb3e2e362f32ff8f9f30b SHA512 d3256c2ff49a7fd0ccfec14ba3e34ed51577841c1670902d25f2a0166e63820428e689c722dddbccf787e1380c7f9a8ddc5b9042a1632b688b151ecce0f6d262
diff --git a/gui-libs/libhandy/libhandy-0.0.13.ebuild b/gui-libs/libhandy/libhandy-0.0.13.ebuild
new file mode 100644
index 000000000000..95e3f6e00d7b
--- /dev/null
+++ b/gui-libs/libhandy/libhandy-0.0.13.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg vala virtualx
+
+MY_P="${PN}-v${PV}"
+DESCRIPTION="Library with GTK widgets for mobile phones"
+HOMEPAGE="https://source.puri.sm/Librem5/libhandy/"
+SRC_URI="https://source.puri.sm/Librem5/libhandy/-/archive/v${PV}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.0/0" # It may or may not break ABI in future versions at this point; if new
+# SLOT happens, it'll likely file conflict on gtk-doc and glade library and catalog
+KEYWORDS="~amd64 ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="examples glade gtk-doc +introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.24.1:3[introspection?]
+	glade? ( dev-util/glade:3.10= )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dprofiling=false # -pg passing
+		-Dstatic=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use test tests)
+		$(meson_use examples)
+		$(meson_feature glade glade_catalog)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
-- 
cgit v1.2.3-65-gdbad