From 03188fbf1ecf7baee654f7eecba3d6e2863b1328 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 10 Jun 2021 14:59:29 +0200
Subject: kde-apps/akonadi: 21.04.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/akonadi/Manifest               |   1 +
 kde-apps/akonadi/akonadi-21.04.2.ebuild | 126 ++++++++++++++++++++++++++++++++
 2 files changed, 127 insertions(+)
 create mode 100644 kde-apps/akonadi/akonadi-21.04.2.ebuild

(limited to 'kde-apps/akonadi')

diff --git a/kde-apps/akonadi/Manifest b/kde-apps/akonadi/Manifest
index c4c447e80d68..df3b67d5821b 100644
--- a/kde-apps/akonadi/Manifest
+++ b/kde-apps/akonadi/Manifest
@@ -1,2 +1,3 @@
 DIST akonadi-20.12.3.tar.xz 1593588 BLAKE2B 783b75a21cf1b1771a5ed25fb25d395af374e249e43ae15f725e92921ef7afdf312cf39c60457a61ba549ba90fc3aebc8ef0b53b666ad1a89ce0cf58c43748b6 SHA512 516f240349b4a680ee8ab1986b8f3d018e9e54a8802aed404b3deb08491edd67413cc4bbb43aedc583f7110812b6bf41277f83908f54221cf21efb3b7f6e32df
 DIST akonadi-21.04.1.tar.xz 1598652 BLAKE2B 67007d4307bd6c223739d1c4c2161fd9f088d5b169dfb10a2705318b7cae5e785198953564d91c7cea73694662c64593bcf24558c001db1ada6fb8a826661beb SHA512 d02359dbd91e52a040e2317a35f3f893666bb41625811aa1765bcbfea2709dc2be5ad22a99dd23d5987367d15a9c815a809a36e58f88afed863e45c393f71091
+DIST akonadi-21.04.2.tar.xz 1610288 BLAKE2B f82b788af4ae7b5c238fa74de071918a3725e680b50ac05059109b6f7739f0ed34f2c98846045baf8ee2ad3b77a46e26f4575acbca74c10ee3c0e677572c3a0c SHA512 24a0105eb8db251f1bb7a2701593f36ae8a02d854d5bc8595a90374b804c7552eee4324729297bf8c6eee0be8ae72b50124f5da063ae334b6c76f6d522b3e824
diff --git a/kde-apps/akonadi/akonadi-21.04.2.ebuild b/kde-apps/akonadi/akonadi-21.04.2.ebuild
new file mode 100644
index 000000000000..7e807c4a6a14
--- /dev/null
+++ b/kde-apps/akonadi/akonadi-21.04.2.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_DESIGNERPLUGIN="true"
+ECM_TEST="forceoptional"
+KFMIN=5.80.0
+QTMIN=5.15.2
+VIRTUALDBUS_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org readme.gentoo-r1
+
+DESCRIPTION="Storage service for PIM data and libraries for PIM apps"
+HOMEPAGE="https://community.kde.org/KDE_PIM/akonadi"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+kaccounts +mysql postgres sqlite tools xml"
+
+REQUIRED_USE="|| ( mysql postgres sqlite ) test? ( tools )"
+
+# some akonadi tests time out, that probably needs more work as it's ~700 tests
+RESTRICT+=" test"
+
+COMMON_DEPEND="
+	app-arch/xz-utils
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[mysql?,postgres?]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	kaccounts? (
+		>=kde-apps/kaccounts-integration-20.08.3:5
+		net-libs/accounts-qt
+	)
+	sqlite? (
+		dev-db/sqlite:3
+		>=dev-qt/qtsql-${QTMIN}:5=[sqlite]
+	)
+	xml? ( dev-libs/libxml2 )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	dev-libs/libxslt
+	test? ( sys-apps/dbus )
+"
+RDEPEND="${COMMON_DEPEND}
+	mysql? ( virtual/mysql )
+	postgres? ( dev-db/postgresql )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-21.03.80-mysql56-crash.patch" )
+
+pkg_setup() {
+	# Set default storage backend in order: MySQL, PostgreSQL, SQLite
+	# reverse driver check to keep the order
+	use sqlite && DRIVER="QSQLITE3"
+	use postgres && DRIVER="QPSQL"
+	use mysql && DRIVER="QMYSQL"
+
+	if use mysql && has_version "${CATEGORY}/${PN}[mysql]" && has_version "dev-db/mariadb"; then
+		ewarn
+		ewarn "Attention: Make sure to read README.gentoo after install."
+		ewarn
+	fi
+
+	if use sqlite || has_version "<${CATEGORY}/${P}[sqlite]"; then
+		ewarn "We strongly recommend you change your Akonadi database backend to"
+		ewarn "either MariaDB/MySQL or PostgreSQL in your user configuration."
+		ewarn "In particular, kde-apps/kmail does not work properly with the sqlite backend."
+	fi
+
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package kaccounts AccountsQt5)
+		$(cmake_use_find_package kaccounts KAccounts)
+		-DAKONADI_BUILD_QSQLITE=$(usex sqlite)
+		-DBUILD_TOOLS=$(usex tools)
+		$(cmake_use_find_package xml LibXml2)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	# Who knows, maybe it accidentally fixes our permission issues
+	cat <<-EOF > "${T}"/akonadiserverrc
+[%General]
+Driver=${DRIVER}
+EOF
+	insinto /usr/share/config/akonadi
+	doins "${T}"/akonadiserverrc
+
+	ecm_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	elog "You can select the storage backend in ~/.config/akonadi/akonadiserverrc."
+	elog "Available drivers are:"
+	use mysql && elog "  QMYSQL"
+	use postgres && elog "  QPSQL"
+	use sqlite && elog "  QSQLITE3"
+	elog "${DRIVER} has been set as your default akonadi storage backend."
+	use mysql && elog
+	use mysql && FORCE_PRINT_ELOG=1 readme.gentoo_print_elog
+}
-- 
cgit v1.2.3-65-gdbad