From 44835f4abe8a7cfc40160bc6520aa8ce829f9d72 Mon Sep 17 00:00:00 2001
From: Bernard Cafarelli <voyageur@gentoo.org>
Date: Tue, 1 Sep 2015 22:59:50 +0200
Subject: media-gfx/geeqie: version bump, allow gtk3 build

Bug: 559262

Package-Manager: portage-2.2.20.1
---
 media-gfx/geeqie/geeqie-1.2.1.ebuild | 71 ++++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)
 create mode 100644 media-gfx/geeqie/geeqie-1.2.1.ebuild

(limited to 'media-gfx/geeqie/geeqie-1.2.1.ebuild')

diff --git a/media-gfx/geeqie/geeqie-1.2.1.ebuild b/media-gfx/geeqie/geeqie-1.2.1.ebuild
new file mode 100644
index 000000000000..d5e374e5e30b
--- /dev/null
+++ b/media-gfx/geeqie/geeqie-1.2.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils
+
+DESCRIPTION="A lightweight GTK image viewer forked from GQview"
+HOMEPAGE="http://www.geeqie.org"
+# Grab from tag snapshot: http://www.geeqie.org/cgi-bin/gitweb.cgi?p=geeqie.git
+SRC_URI="https://dev.gentoo.org/~voyageur/distfiles/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc exif gtk3 jpeg lcms lirc lua tiff xmp"
+
+RDEPEND="gtk3? ( x11-libs/gtk+:3 )
+	!gtk3? ( x11-libs/gtk+:2 )
+	virtual/libintl
+	doc? ( app-text/gnome-doc-utils )
+	jpeg? ( virtual/jpeg:0 )
+	lcms? ( media-libs/lcms:2 )
+	lirc? ( app-misc/lirc )
+	lua? ( >=dev-lang/lua-5.1:= )
+	xmp? ( >=media-gfx/exiv2-0.17:=[xmp] )
+	!xmp? ( exif? ( >=media-gfx/exiv2-0.17 ) )
+	tiff? ( media-libs/tiff:0 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	dev-util/intltool
+	sys-devel/gettext"
+
+src_prepare() {
+	epatch_user
+
+	eautoreconf
+}
+
+src_configure() {
+	# Force disable experimental stuff
+	local myconf="--disable-dependency-tracking
+		--with-readmedir=/usr/share/doc/${PF}
+		--disable-clutter
+		--disable-gps
+		$(use_enable gtk3)
+		$(use_enable jpeg)
+		$(use_enable lcms)
+		$(use_enable lua)
+		$(use_enable lirc)
+		$(use_enable tiff)"
+
+	if use exif || use xmp; then
+		myconf="${myconf} --enable-exiv2"
+	else
+		myconf="${myconf} --disable-exiv2"
+	fi
+
+	econf ${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	rm -f "${D}/usr/share/doc/${MY_P}/COPYING"
+}
+
+pkg_postinst() {
+	elog "Some plugins may require additional packages"
+	elog "- Image rotate plugin: media-gfx/fbida (JPEG), media-gfx/imagemagick (TIFF/PNG)"
+	elog "- RAW images plugin: media-gfx/ufraw"
+}
-- 
cgit v1.2.3-65-gdbad