From f672630753e845b9e9b2bc3f02d3a1ad35c40000 Mon Sep 17 00:00:00 2001
From: Markus Meier <maekke@gentoo.org>
Date: Sun, 4 Feb 2018 18:11:50 +0100
Subject: media-gfx/hugin: fix version number

Package-Manager: Portage-2.3.19, Repoman-2.3.6
---
 media-gfx/hugin/hugin-2018.0.0.ebuild | 89 +++++++++++++++++++++++++++++++++++
 1 file changed, 89 insertions(+)
 create mode 100644 media-gfx/hugin/hugin-2018.0.0.ebuild

(limited to 'media-gfx/hugin/hugin-2018.0.0.ebuild')

diff --git a/media-gfx/hugin/hugin-2018.0.0.ebuild b/media-gfx/hugin/hugin-2018.0.0.ebuild
new file mode 100644
index 000000000000..33d44b9ffacf
--- /dev/null
+++ b/media-gfx/hugin/hugin-2018.0.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+WX_GTK_VER="3.0"
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit python-single-r1 wxwidgets versionator cmake-utils
+
+DESCRIPTION="GUI for the creation & processing of panoramic images"
+HOMEPAGE="http://hugin.sf.net"
+SRC_URI="mirror://sourceforge/${PN}/${P/_/}.tar.bz2"
+
+LICENSE="GPL-2 SIFT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+LANGS=" ca ca-valencia cs da de en-GB es eu fi fr hu it ja nl pl pt-BR ro ru sk sv zh-CN zh-TW"
+IUSE="debug lapack python sift $(echo ${LANGS//\ /\ l10n_})"
+
+CDEPEND="
+	!!dev-util/cocom
+	dev-db/sqlite:3
+	dev-libs/boost:=
+	dev-libs/zthread
+	>=media-gfx/enblend-4.0
+	media-gfx/exiv2:=
+	media-libs/freeglut
+	media-libs/glew:=
+	>=media-libs/libpano13-2.9.19_beta1:0=
+	media-libs/libpng:0=
+	media-libs/openexr:=
+	media-libs/tiff:0
+	>=media-libs/vigra-1.11.0[openexr]
+	sci-libs/fftw:3.0=
+	sci-libs/flann
+	sys-libs/zlib
+	virtual/glu
+	virtual/jpeg:0
+	virtual/opengl
+	x11-libs/wxGTK:3.0=[X,opengl]
+	lapack? ( virtual/blas virtual/lapack )
+	python? ( ${PYTHON_DEPS} )
+	sift? ( media-gfx/autopano-sift-C )"
+RDEPEND="${CDEPEND}
+	media-libs/exiftool"
+DEPEND="${CDEPEND}
+	dev-cpp/tclap
+	sys-devel/gettext
+	virtual/pkgconfig
+	python? ( >=dev-lang/swig-2.0.4 )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DOCS=( authors.txt README TODO )
+
+S=${WORKDIR}/${PN}-$(get_version_component_range 1-2).0
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	setup-wxwidgets
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_HSI=$(usex python)
+		-DENABLE_LAPACK=$(usex lapack)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	use python && python_optimize
+
+	local lang
+	for lang in ${LANGS} ; do
+		case ${lang} in
+			ca) dir=ca_ES;;
+			ca-valencia) dir=ca_ES@valencia;;
+			cs) dir=cs_CZ;;
+			*) dir=${lang/-/_};;
+		esac
+		if ! use l10n_${lang} ; then
+			rm -r "${ED%/}"/usr/share/locale/${dir} || die
+		fi
+	done
+}
-- 
cgit v1.2.3-65-gdbad