From ba61a592f0b27107872484bfbf58d0a7204e37a8 Mon Sep 17 00:00:00 2001
From: Pacho Ramos <pacho@gentoo.org>
Date: Sun, 16 Oct 2016 10:39:49 +0200
Subject: media-gfx/metapixel: Fix giflib-5 building (#571934)

Package-Manager: portage-2.3.1
---
 media-gfx/metapixel/metapixel-1.0.2-r1.ebuild | 45 +++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 media-gfx/metapixel/metapixel-1.0.2-r1.ebuild

(limited to 'media-gfx/metapixel/metapixel-1.0.2-r1.ebuild')

diff --git a/media-gfx/metapixel/metapixel-1.0.2-r1.ebuild b/media-gfx/metapixel/metapixel-1.0.2-r1.ebuild
new file mode 100644
index 000000000000..43e9ad50f1f0
--- /dev/null
+++ b/media-gfx/metapixel/metapixel-1.0.2-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit toolchain-funcs
+
+DESCRIPTION="a program for generating photomosaics"
+HOMEPAGE="http://www.complang.tuwien.ac.at/schani/metapixel"
+SRC_URI="http://www.complang.tuwien.ac.at/schani/${PN}/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-lang/perl
+	>=media-libs/giflib-5:0=
+	>=media-libs/libpng-1.4:0=
+	virtual/jpeg:0
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-libpng15.patch
+	"${FILESDIR}"/${P}-giflib5.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e 's:/usr/X11R6:/usr:g' Makefile || die
+	sed -i -e 's:ar:$(AR):' rwimg/Makefile || die
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" CC="$(tc-getCC)" OPTIMIZE="${CFLAGS}" LDOPTS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin ${PN}{,-prepare,-imagesize,-sizesort}
+	doman ${PN}.1
+	dodoc NEWS README
+}
-- 
cgit v1.2.3-65-gdbad