From fa139b17c6a908c7a46d2d3a3051b5209298af52 Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Fri, 17 Jul 2020 23:33:05 +0300
Subject: media-gfx/simple-scan: bump to 3.36.4

Closes: https://bugs.gentoo.org/729360
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 media-gfx/simple-scan/Manifest                  |  1 +
 media-gfx/simple-scan/simple-scan-3.36.4.ebuild | 70 +++++++++++++++++++++++++
 2 files changed, 71 insertions(+)
 create mode 100644 media-gfx/simple-scan/simple-scan-3.36.4.ebuild

(limited to 'media-gfx')

diff --git a/media-gfx/simple-scan/Manifest b/media-gfx/simple-scan/Manifest
index f21314a075ae..a43c9c7858a6 100644
--- a/media-gfx/simple-scan/Manifest
+++ b/media-gfx/simple-scan/Manifest
@@ -1 +1,2 @@
 DIST simple-scan-3.34.6.tar.xz 801064 BLAKE2B 94c6bc386c2d7701bd13067e384eb294ce145d2e02d66e366e76a2c85fb5e3ac4e9bae0efa37fe13d3fc857b57c1730bf01961f7968d6744a4ea4dc47308cb23 SHA512 7b2d0eab13f08d4110d2143c4572e249297891e3868e6eb178a7a765b2d56960820931fbda538ede318014c578871657aa0e27518d184f861efc18ad4fdd900c
+DIST simple-scan-3.36.4.tar.xz 914688 BLAKE2B ae972cf6b5085d0e79fdfa9250aed655051b97239988b410e175b3058dda3ed5dc19b6574c015dd9a7afcbefd4d05cce6120b3648c061ff1e52043f866769a62 SHA512 780eeabd9593f14b2b04b9474bb1faebe3a32a7fd7e6b067c144fe44ad9b880f307bf80a8a925fb2549ca0b8172357c9a393146dfabd4b68bfc4396c32de4fa8
diff --git a/media-gfx/simple-scan/simple-scan-3.36.4.ebuild b/media-gfx/simple-scan/simple-scan-3.36.4.ebuild
new file mode 100644
index 000000000000..a7a3d720bbeb
--- /dev/null
+++ b/media-gfx/simple-scan/simple-scan-3.36.4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_MIN_API_VERSION="0.34"
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="Simple document scanning utility"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/simple-scan"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="colord webp"
+
+DEPEND="
+	>=dev-libs/glib-2.38:2
+	>=x11-libs/gtk+-3.22:3
+	>=sys-libs/zlib-1.2.3.1:=
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:2
+	>=dev-libs/libgusb-0.2.7
+	colord? ( >=x11-misc/colord-0.1.24:=[udev] )
+	webp? ( media-libs/libwebp )
+	>=media-gfx/sane-backends-1.0.20:=
+
+	virtual/jpeg:0=
+"
+# packagekit? ( >=app-admin/packagekit-base-1.1.5 )
+RDEPEND="${DEPEND}
+	x11-misc/xdg-utils
+"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	dev-libs/libgusb[vala]
+	colord? ( x11-misc/colord[vala] )
+"
+
+PATCHES=(
+	# Add control for optional dependencies
+	"${FILESDIR}"/3.26-add-control-optional-deps.patch
+)
+
+src_prepare() {
+	vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use colord)
+		-Dpackagekit=false
+		$(meson_use webp)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3-65-gdbad