From a774626e5c4f2ad124561c276aedec064cdde004 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Tue, 20 Oct 2020 09:09:04 +0200
Subject: media-libs/faad2: Bump to version 2.10.0

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 media-libs/faad2/faad2-2.10.0.ebuild | 52 ++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 media-libs/faad2/faad2-2.10.0.ebuild

(limited to 'media-libs/faad2/faad2-2.10.0.ebuild')

diff --git a/media-libs/faad2/faad2-2.10.0.ebuild b/media-libs/faad2/faad2-2.10.0.ebuild
new file mode 100644
index 000000000000..4c6a8bef3075
--- /dev/null
+++ b/media-libs/faad2/faad2-2.10.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+MY_PV="$(ver_rs 1- _)"
+
+DESCRIPTION="AAC audio decoding library"
+HOMEPAGE="https://www.audiocoding.com/faad2.html"
+SRC_URI="https://github.com/knik0/faad2/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="digitalradio static-libs"
+
+RDEPEND=""
+DEPEND=""
+
+DOCS=( AUTHORS ChangeLog NEWS README TODO )
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+src_prepare() {
+	default
+
+	sed -i -e 's:iquote :I:' libfaad/Makefile.am || die
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myconf=(
+		--without-xmms
+		$(use_with digitalradio drm)
+		$(use_enable static-libs static)
+	)
+
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+
+	# do not build the frontend for non default abis
+	if [ "${ABI}" != "${DEFAULT_ABI}" ] ; then
+		sed -i -e 's/frontend//' Makefile || die
+	fi
+}
+
+multilib_src_install_all() {
+	find "${ED}" -type f -name '*.la' -delete || die
+	einstalldocs
+}
-- 
cgit v1.2.3-65-gdbad