From ce78ee23ae96457a915ae2939544608236922b5d Mon Sep 17 00:00:00 2001
From: Miroslav Šulc <fordfrog@gentoo.org>
Date: Tue, 24 Oct 2023 20:22:20 +0200
Subject: media-libs/sratom: bump to 0.6.16 + py3.12
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
---
 media-libs/sratom/sratom-0.6.16.ebuild | 58 ++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 media-libs/sratom/sratom-0.6.16.ebuild

(limited to 'media-libs/sratom/sratom-0.6.16.ebuild')

diff --git a/media-libs/sratom/sratom-0.6.16.ebuild b/media-libs/sratom/sratom-0.6.16.ebuild
new file mode 100644
index 000000000000..787d7e0e66de
--- /dev/null
+++ b/media-libs/sratom/sratom-0.6.16.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+PYTHON_REQ_USE='threads(+)'
+inherit meson-multilib python-any-r1
+
+DESCRIPTION="Library for serialising LV2 atoms to/from RDF, particularly the Turtle syntax"
+HOMEPAGE="https://drobilla.net/software/sratom.html"
+SRC_URI="https://download.drobilla.net/${P}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-python/sphinx
+		dev-python/sphinx-lv2-theme
+		dev-python/sphinxygen
+)
+"
+# Take care on bumps to check minimum versions!
+RDEPEND="
+	dev-libs/serd
+	>=dev-libs/sord-0.16.16
+	media-libs/lv2
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+"
+
+src_prepare() {
+	default
+
+	# fix doc installation path
+	sed -iE "s/versioned_name/'${PF}'/g" doc/html/meson.build doc/singlehtml/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_feature doc docs)
+		$(meson_feature test tests)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_install_all() {
+	local DOCS=( NEWS README.md )
+	einstalldocs
+}
-- 
cgit v1.2.3-65-gdbad