From 706c6b2bc0ee24fd42883af92d3e3e5d05d854b6 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 3 Sep 2020 11:21:09 +0200
Subject: media-sound/elisa: 20.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 media-sound/elisa/Manifest             |  1 +
 media-sound/elisa/elisa-20.08.1.ebuild | 64 ++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)
 create mode 100644 media-sound/elisa/elisa-20.08.1.ebuild

(limited to 'media-sound/elisa')

diff --git a/media-sound/elisa/Manifest b/media-sound/elisa/Manifest
index 2f42dbff6ce4..e78184dd2a42 100644
--- a/media-sound/elisa/Manifest
+++ b/media-sound/elisa/Manifest
@@ -1,2 +1,3 @@
 DIST elisa-20.04.3.tar.xz 1409336 BLAKE2B a1432294cb46562145ecb6f41b07a8a1ae352abffd40253670ef17b79e27b221b2589bf14934a7ce4e0001f90e84a0889a1b0c4dd069101e2e614f1fc51a20cc SHA512 00afa92eaab736f5f38759a3076b9f579ee3f5fce84404042a73e11cdfe0e004b32a83f9e542ca6d0a962d66bcb3fcce9d12fc5dbdd8f937d9d4cea9321687b4
 DIST elisa-20.08.0.tar.xz 1634132 BLAKE2B bd2286863376e9a376d160663a54b49f1c66bcc4078d9fef3da6672352e45c82bb173e86e04410eb8866f949bf754c14377de1e705c80c56591f6515c1cf5874 SHA512 e4f7352c00199ba0780199a5c7f72ea4f7954bae575dc6fce9786f8957053b34d08877a82c3888495ad4915668c494ddd1388e8fd4173f5e805e229ae7541d62
+DIST elisa-20.08.1.tar.xz 1634492 BLAKE2B 2ea1f8eb1c6e20d7b0e383fc660af2605a30f174110f0ece059d4c063e62811ae8c0ff89225429c00977633d29315e5bbb89e7207a2ca4c6c49fb450fdf25ab2 SHA512 a273fe799c701f1acad3966b382189aa69448ee5b0532ea7c47744f0a350c0125193a49d6a100efd448cfcbc878fb45c6fbc248d9135155fad5fac554b673c93
diff --git a/media-sound/elisa/elisa-20.08.1.ebuild b/media-sound/elisa/elisa-20.08.1.ebuild
new file mode 100644
index 000000000000..a3e77d8776db
--- /dev/null
+++ b/media-sound/elisa/elisa-20.08.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+KDE_RELEASE_SERVICE="true"
+KFMIN=5.72.0
+QTMIN=5.14.2
+inherit ecm kde.org
+
+DESCRIPTION="Simple music player by KDE"
+HOMEPAGE="https://kde.org/applications/multimedia/org.kde.elisa
+https://community.kde.org/Elisa"
+
+LICENSE="LGPL-3+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="mpris semantic-desktop +vlc"
+
+BDEPEND="sys-devel/gettext"
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kfilemetadata-${KFMIN}:5[taglib]
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	mpris? (
+		>=dev-qt/qtdbus-${QTMIN}:5
+		>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	)
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+	vlc? ( media-video/vlc:= )
+	!vlc? ( >=dev-qt/qtmultimedia-${QTMIN}:5[gstreamer] )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+"
+
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package mpris KF5DBusAddons)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package vlc LIBVLC)
+	)
+
+	ecm_src_configure
+}
-- 
cgit v1.2.3-65-gdbad