From ad8ce64d3ceff42591913463a97612d9b76242b8 Mon Sep 17 00:00:00 2001
From: Göktürk Yüksek <gokturk@gentoo.org>
Date: Tue, 4 Oct 2016 07:32:25 -0400
Subject: media-sound/playerctl: initial commit with version 0.5.0

playerctl is a mpris command-line controller and library for spotify,
vlc, audacious, bmp, xmms2, and others.

Package-Manager: portage-2.3.0
---
 media-sound/playerctl/playerctl-0.5.0.ebuild | 51 ++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 media-sound/playerctl/playerctl-0.5.0.ebuild

(limited to 'media-sound/playerctl/playerctl-0.5.0.ebuild')

diff --git a/media-sound/playerctl/playerctl-0.5.0.ebuild b/media-sound/playerctl/playerctl-0.5.0.ebuild
new file mode 100644
index 000000000000..7f5b861c3997
--- /dev/null
+++ b/media-sound/playerctl/playerctl-0.5.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools
+
+DESCRIPTION="A CLI utility to control media players over MPRIS"
+HOMEPAGE="https://github.com/acrisci/playerctl"
+SRC_URI="https://github.com/acrisci/playerctl/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc introspection"
+
+RDEPEND="
+	dev-libs/glib:2
+	introspection? ( dev-libs/gobject-introspection )
+"
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	dev-util/gtk-doc-am
+	doc? ( dev-util/gtk-doc )
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	if ! use doc; then
+		echo 'EXTRA_DIST = ' > gtk-doc.make || die
+	fi
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable doc gtk-doc) \
+		$(use_enable doc gtk-doc-html) \
+		$(use_enable introspection)
+}
+
+src_compile() {
+	emake -j1
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-18-g5258