From f299f49c951d680113412807a38a90c5024aba57 Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Sun, 27 Sep 2020 12:06:06 +0200
Subject: net-analyzer/fragroute: Depend on >=dev-libs/libdnet-1.14-r1

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Bug: https://bugs.gentoo.org/744484
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 net-analyzer/fragroute/fragroute-1.2.6-r4.ebuild | 54 ++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 net-analyzer/fragroute/fragroute-1.2.6-r4.ebuild

(limited to 'net-analyzer')

diff --git a/net-analyzer/fragroute/fragroute-1.2.6-r4.ebuild b/net-analyzer/fragroute/fragroute-1.2.6-r4.ebuild
new file mode 100644
index 000000000000..58e9d754203b
--- /dev/null
+++ b/net-analyzer/fragroute/fragroute-1.2.6-r4.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+MY_P="${P}-ipv6"
+inherit autotools
+
+DESCRIPTION="Testing of network intrusion detection systems, firewalls and TCP/IP stacks"
+HOMEPAGE="https://github.com/stsi/fragroute-ipv6"
+SRC_URI="https://fragroute-ipv6.googlecode.com/files/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+RDEPEND="
+	>=dev-libs/libdnet-1.14-r1
+	dev-libs/libevent:=
+	net-libs/libpcap
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	virtual/awk
+"
+DOCS=( INSTALL README TODO )
+PATCHES=(
+	"${FILESDIR}"/${P}-libdir.patch
+	"${FILESDIR}"/${P}-pcap_open.patch
+)
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+
+	# Remove broken and old files, autotools will regen needed files
+	rm *.m4 acconfig.h missing Makefile.in || die
+
+	# Add missing includes
+	sed -i -e "/#define IPUTIL_H/a#include <stdio.h>\n#include <stdint.h>" iputil.h || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		DNETINC='' \
+		DNETLIB=-ldnet \
+		EVENTINC='' \
+		EVENTLIB=-levent \
+		PCAPINC='' \
+		PCAPLIB=-lpcap
+}
-- 
cgit v1.2.3-65-gdbad