From 285a78869a91ee880369c230ab3fe241ca3d05b9 Mon Sep 17 00:00:00 2001
From: Bernard Cafarelli <voyageur@gentoo.org>
Date: Thu, 6 Dec 2018 23:19:43 +0100
Subject: net-misc/csync: fix compilation with GCC 8

Update ebuild (EAPI, patch, samba conditional)

Closes: https://bugs.gentoo.org/671094
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
---
 net-misc/csync/csync-0.50.0-r1.ebuild | 47 +++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 net-misc/csync/csync-0.50.0-r1.ebuild

(limited to 'net-misc/csync/csync-0.50.0-r1.ebuild')

diff --git a/net-misc/csync/csync-0.50.0-r1.ebuild b/net-misc/csync/csync-0.50.0-r1.ebuild
new file mode 100644
index 000000000000..5374066247df
--- /dev/null
+++ b/net-misc/csync/csync-0.50.0-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="lightweight file synchronizer utility"
+HOMEPAGE="https://www.csync.org/"
+SRC_URI="https://open.cryptomilk.org/attachments/download/27/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc iconv samba +sftp test"
+
+RDEPEND=">=dev-db/sqlite-3.4:3
+	net-libs/neon[ssl]
+	iconv? ( virtual/libiconv )
+	samba? ( >=net-fs/samba-3.5 )
+	sftp? ( >=net-libs/libssh-0.5 )
+	!net-misc/ocsync"
+DEPEND="${RDEPEND}
+	app-text/asciidoc
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cmocka )"
+
+PATCHES=( "${FILESDIR}"/${P}-gcc_5_and_8.patch )
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# proper docdir
+	sed -e "s:/doc/${PN}:/doc/${PF}:" \
+		-i doc/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DWITH_ICONV="$(usex iconv)"
+		-DUNIT_TESTING="$(usex test)"
+		$(cmake-utils_use_find_package doc Doxygen)
+		$(cmake-utils_use_find_package samba SMBClient)
+		$(cmake-utils_use_find_package sftp LibSSH)
+	)
+	cmake-utils_src_configure
+}
-- 
cgit v1.2.3-65-gdbad