From 5039197908326c14dbcb967014d2df5e3f6c6f90 Mon Sep 17 00:00:00 2001
From: Patrick McLean <chutzpah@gentoo.org>
Date: Thu, 9 Jun 2022 15:20:29 -0700
Subject: net-misc/exabgp: Drop py311 due to nose dep

Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
---
 net-misc/exabgp/exabgp-4.2.19-r1.ebuild | 64 +++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 net-misc/exabgp/exabgp-4.2.19-r1.ebuild

(limited to 'net-misc/exabgp/exabgp-4.2.19-r1.ebuild')

diff --git a/net-misc/exabgp/exabgp-4.2.19-r1.ebuild b/net-misc/exabgp/exabgp-4.2.19-r1.ebuild
new file mode 100644
index 000000000000..618539f9bee6
--- /dev/null
+++ b/net-misc/exabgp/exabgp-4.2.19-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit tmpfiles systemd distutils-r1
+
+DESCRIPTION="The BGP swiss army knife of networking"
+HOMEPAGE="https://github.com/Exa-Networks/exabgp"
+SRC_URI="https://github.com/Exa-Networks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-group/exabgp
+	acct-user/exabgp
+"
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/exabgp-4.2.7-paths.patch"
+	"${FILESDIR}/exabgp-4.2.10-ip-path.patch"
+	"${FILESDIR}/exabgp-4.2.11-healthcheck-allow-disable-metric.patch"
+	"${FILESDIR}/exabgp-4.2.11-healthcheck-fix-log-crash.patch"
+	"${FILESDIR}/exabgp-4.2.11-less-verbose-logging.patch"
+)
+
+python_test() {
+	./qa/bin/parsing || die "tests fail with ${EPYTHON}"
+	nosetests -v ./qa/tests/*_test.py || die "tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newinitd "${FILESDIR}/${PN}.initd-r2" ${PN}
+	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+
+	newtmpfiles "${FILESDIR}/exabgp.tmpfiles" ${PN}.conf
+	systemd_dounit etc/systemd/*
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotate" ${PN}
+
+	keepdir /etc/exabgp
+
+	doman doc/man/*.?
+}
+
+pkg_postinst() {
+	tmpfiles_process ${PN}.conf
+}
-- 
cgit v1.2.3-65-gdbad