From 874525abe06f93a786d21984ff5d0261b00394af Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Sun, 6 Jun 2021 14:34:06 -0700
Subject: net-misc/modemmanager: Version bump to 1.16.6

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 net-misc/modemmanager/Manifest                   |   1 +
 net-misc/modemmanager/modemmanager-1.16.6.ebuild | 128 +++++++++++++++++++++++
 2 files changed, 129 insertions(+)
 create mode 100644 net-misc/modemmanager/modemmanager-1.16.6.ebuild

(limited to 'net-misc/modemmanager')

diff --git a/net-misc/modemmanager/Manifest b/net-misc/modemmanager/Manifest
index fdf4d25dc36f..43b9ba6d6b16 100644
--- a/net-misc/modemmanager/Manifest
+++ b/net-misc/modemmanager/Manifest
@@ -1 +1,2 @@
 DIST ModemManager-1.16.4.tar.xz 2335908 BLAKE2B dfd3293e9b685d3b01fa3deec111aafca6f11dc27be0a69e0496036e537eecb6f51f592ce1996f47c86b5d9db2abf3c9b9a26e66e9f058ba59982caf38b28ef9 SHA512 5fb7625c9d41ce0179b4e59745b00b815038239552a5438d71ff36b019b398fc3dc6bef709e91a186f5f7427fcb59d79c0b1c3ca9c3dca867f0d5677fd979506
+DIST ModemManager-1.16.6.tar.xz 2339528 BLAKE2B b76a8b6959d988a27d411384440b9bd1b7ac1a9d780b77319e735c4b42c55c51f51304ae936aa9b385634640bcb1a55696d4bd25ffdaf88eb73839bfefe5e091 SHA512 78a928007732baaa0eaed9d587913774d4fb79049d652474f39176190496012dc4c93fd0bd774ed6f86f845f3b9f345bcccf4c7b2438b83cf5846b2bcdcb39d5
diff --git a/net-misc/modemmanager/modemmanager-1.16.6.ebuild b/net-misc/modemmanager/modemmanager-1.16.6.ebuild
new file mode 100644
index 000000000000..d831eb774edc
--- /dev/null
+++ b/net-misc/modemmanager/modemmanager-1.16.6.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 readme.gentoo-r1 systemd toolchain-funcs udev vala
+
+DESCRIPTION="Modem and mobile broadband management libraries"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/ModemManager/"
+SRC_URI="https://www.freedesktop.org/software/ModemManager/ModemManager-${PV}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0/1" # subslot = dbus interface version, i.e. N in org.freedesktop.ModemManager${N}
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="elogind +introspection mbim policykit +qmi systemd +udev vala"
+REQUIRED_USE="
+	?? ( elogind systemd )
+	vala? ( introspection )
+"
+
+DEPEND="
+	>=dev-libs/glib-2.48.0:2
+	udev? ( >=dev-libs/libgudev-230:= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+	mbim? ( >=net-libs/libmbim-1.24.0 )
+	policykit? ( >=sys-auth/polkit-0.106[introspection?] )
+	qmi? ( >=net-libs/libqmi-1.28.6:= )
+	elogind? ( sys-auth/elogind )
+	systemd? ( >=sys-apps/systemd-209 )
+"
+RDEPEND="${DEPEND}
+	policykit? ( acct-group/plugdev )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+S="${WORKDIR}/ModemManager-${PV}"
+
+src_prepare() {
+	DOC_CONTENTS="
+		If your USB modem shows up only as a storage device when you plug it in,
+		then you should install sys-apps/usb_modeswitch, which will automatically
+		switch it over to USB modem mode whenever you plug it in.\n"
+
+	if use policykit; then
+		DOC_CONTENTS+="\nTo control your modem without needing to enter the root password,
+			add your user account to the 'plugdev' group."
+	fi
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=(
+		--disable-Werror
+		--disable-static
+		--with-dist-version=${PVR}
+		--with-udev-base-dir="$(get_udevdir)"
+		$(use_with udev)
+		$(use_enable introspection)
+		$(use_with mbim)
+		$(use_with policykit polkit)
+		$(use_with systemd systemd-journal)
+		$(use_with qmi)
+		$(use_enable vala)
+	)
+	if use systemd || use elogind; then
+		myconf+=(--with-systemd-suspend-resume)
+	else
+		myconf+=(--without-systemd-suspend-resume)
+	fi
+	gnome2_src_configure "${myconf[@]}"
+}
+
+src_install() {
+	gnome2_src_install
+
+	# Allow users in plugdev group full control over their modem
+	if use policykit; then
+		insinto /usr/share/polkit-1/rules.d/
+		doins "${FILESDIR}"/01-org.freedesktop.ModemManager1.rules
+	fi
+
+	readme.gentoo_create_doc
+
+	newinitd "${FILESDIR}/modemmanager.initd" modemmanager
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	# The polkit rules file moved to /usr/share
+	old_rules="${EROOT}/etc/polkit-1/rules.d/01-org.freedesktop.ModemManager.rules"
+	if [[ -f "${old_rules}" ]]; then
+		case "$(md5sum ${old_rules})" in
+		  c5ff02532cb1da2c7545c3069e5d0992* | 5c50f0dc603c0a56e2851a5ce9389335* )
+			# Automatically delete the old rules.d file if the user did not change it
+			elog
+			elog "Removing old ${old_rules} ..."
+			rm -f "${old_rules}" || eerror "Failed, please remove ${old_rules} manually"
+			;;
+		  * )
+			elog "The ${old_rules}"
+			elog "file moved to /usr/share/polkit-1/rules.d/ in >=modemmanager-0.5.2.0-r2"
+			elog "If you edited ${old_rules}"
+			elog "without changing its behavior, you may want to remove it."
+			;;
+		esac
+	fi
+
+	if ! use udev; then
+		ewarn "You have built ModemManager without udev support. You may have to teach it"
+		ewarn "about your modem port manually."
+	fi
+
+	systemd_reenable ModemManager.service
+
+	readme.gentoo_print_elog
+}
-- 
cgit v1.2.3-65-gdbad