From 487449d882b95ff9d88657746ee835553e461a27 Mon Sep 17 00:00:00 2001
From: NP-Hardass <NP-Hardass@gentoo.org>
Date: Wed, 20 Sep 2017 17:48:21 -0400
Subject: net-misc/vde: Revbump to 2.3.2-r4, EAPI bump

Acked-By: mjo@gentoo.org
Bug: https://bugs.gentoo.org/603382
Package-Manager: Portage-2.3.8, Repoman-2.3.3
---
 net-misc/vde/vde-2.3.2-r4.ebuild | 66 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 net-misc/vde/vde-2.3.2-r4.ebuild

(limited to 'net-misc/vde/vde-2.3.2-r4.ebuild')

diff --git a/net-misc/vde/vde-2.3.2-r4.ebuild b/net-misc/vde/vde-2.3.2-r4.ebuild
new file mode 100644
index 000000000000..105d24c63bf4
--- /dev/null
+++ b/net-misc/vde/vde-2.3.2-r4.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit ltprune python-single-r1 user
+
+MY_P="${PN}2-${PV}"
+
+DESCRIPTION="Virtual distributed ethernet emulator for emulators like qemu, bochs, and uml"
+SRC_URI="mirror://sourceforge/vde/${MY_P}.tar.bz2"
+HOMEPAGE="http://vde.sourceforge.net/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="pcap python selinux ssl libressl static-libs"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPS="pcap? ( net-libs/libpcap )
+	python? ( ${PYTHON_DEPS} )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+DEPEND="${COMMON_DEPS}"
+RDEPEND="${COMMON_DEPS}
+	selinux? ( sec-policy/selinux-vde )"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	# default group already used in kqemu
+	enewgroup qemu
+
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	econf \
+		$(use_enable pcap) \
+		$(use_enable python) \
+		$(use_enable ssl cryptcab) \
+		$(use_enable static-libs static)
+}
+
+src_compile() {
+	emake -j1
+}
+
+src_install() {
+	default
+	prune_libtool_files
+
+	newinitd "${FILESDIR}"/vde.init-r1 vde
+	newconfd "${FILESDIR}"/vde.conf-r1 vde
+}
+
+pkg_postinst() {
+	einfo "To start vde automatically add it to the default runlevel:"
+	einfo "# rc-update add vde default"
+	einfo "You need to setup tap0 in /etc/conf.d/net"
+	einfo "To use it as an user be sure to set a group in /etc/conf.d/vde"
+}
-- 
cgit v1.2.3-65-gdbad