From 6da5e14856696452f2a84c3163b444bd31642c57 Mon Sep 17 00:00:00 2001
From: Yuri Konotopov <ykonotopov@gnome.org>
Date: Tue, 8 May 2018 09:01:16 +0400
Subject: new-news/liferea: version bump to 1.12.3

Closes: https://bugs.gentoo.org/654616
Closes: https://github.com/gentoo/gentoo/pull/8312
---
 net-news/liferea/liferea-1.12.3.ebuild | 60 ++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 net-news/liferea/liferea-1.12.3.ebuild

(limited to 'net-news/liferea/liferea-1.12.3.ebuild')

diff --git a/net-news/liferea/liferea-1.12.3.ebuild b/net-news/liferea/liferea-1.12.3.ebuild
new file mode 100644
index 000000000000..8df197e80aae
--- /dev/null
+++ b/net-news/liferea/liferea-1.12.3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+GNOME2_EAUTORECONF="yes"
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit gnome2 pax-utils python-single-r1
+
+MY_P=${P/_/-}
+
+DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo feeds"
+HOMEPAGE="https://lzone.de/liferea/"
+SRC_URI="https://github.com/lwindolf/${PN}/releases/download/v${PV/_/-}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-db/sqlite-3.7.0:3
+	>=dev-libs/glib-2.28.0:2
+	dev-libs/gobject-introspection
+	dev-libs/json-glib
+	>=dev-libs/libpeas-1.0.0[gtk,python,${PYTHON_USEDEP}]
+	>=dev-libs/libxml2-2.6.27:2
+	>=dev-libs/libxslt-1.1.19
+	gnome-base/gsettings-desktop-schemas
+	>=net-libs/libsoup-2.42:2.4
+	net-libs/webkit-gtk:4
+	x11-libs/gtk+:3
+	>=x11-libs/pango-1.4.0"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig"
+
+S="${WORKDIR}"/${MY_P}
+
+src_configure() {
+	gnome2_src_configure --disable-schemas-compile
+}
+
+src_install() {
+	gnome2_src_install
+
+	# bug #338213
+	# Uses webkit's JIT. Needs mmap('rwx') to generate code in runtime.
+	# MPROTECT policy violation. Will sit here until webkit will
+	# get optional JIT.
+	pax-mark m "${ED%/}"/usr/bin/liferea
+}
+
+pkg_postinst() {
+	elog "If you want to enhance the functionality of this package,"
+	elog "you should consider installing:"
+	elog "    net-misc/networkmanager"
+}
-- 
cgit v1.2.3