From 3f4901e8b7585721fae243d46c7aa1e1f0901985 Mon Sep 17 00:00:00 2001
From: Ionen Wolkens <ionen@gentoo.org>
Date: Fri, 30 Sep 2022 04:34:48 -0400
Subject: sci-calculators/hexcalc: EAPI6->8, fix license, drop dead HOMEPAGE

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
---
 sci-calculators/hexcalc/hexcalc-1.11-r4.ebuild | 49 ++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 sci-calculators/hexcalc/hexcalc-1.11-r4.ebuild

(limited to 'sci-calculators/hexcalc/hexcalc-1.11-r4.ebuild')

diff --git a/sci-calculators/hexcalc/hexcalc-1.11-r4.ebuild b/sci-calculators/hexcalc/hexcalc-1.11-r4.ebuild
new file mode 100644
index 000000000000..e3c78faf52ab
--- /dev/null
+++ b/sci-calculators/hexcalc/hexcalc-1.11-r4.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Simple hex calculator for X"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="mirror://gentoo/${P}.tar.Z"
+S="${WORKDIR}/${PN}"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXaw
+	x11-libs/libXt"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="
+	app-text/rman
+	>=x11-misc/imake-1.0.8-r1"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-keypad.diff
+	"${FILESDIR}"/${PN}-order.diff
+)
+
+src_configure() {
+	CC="$(tc-getBUILD_CC)" LD="$(tc-getLD)" \
+		IMAKECPP="${IMAKECPP:-$(tc-getCPP)}" xmkmf || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		CCLINK="$(tc-getCC)" \
+		LDOPTIONS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin ${PN}
+	newman ${PN}.{man,1}
+}
-- 
cgit v1.2.3-65-gdbad