From fe7e76f2e53fa60d515458210c8d9ea049075145 Mon Sep 17 00:00:00 2001
From: "Andreas K. Hüttel" <dilfridge@gentoo.org>
Date: Sun, 2 Oct 2022 17:39:12 +0200
Subject: sci-libs/linux-gpib-modules: Version bump
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Bug: https://bugs.gentoo.org/873382
Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>
---
 .../linux-gpib-modules-4.3.5.ebuild                | 69 ++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 sci-libs/linux-gpib-modules/linux-gpib-modules-4.3.5.ebuild

(limited to 'sci-libs/linux-gpib-modules/linux-gpib-modules-4.3.5.ebuild')

diff --git a/sci-libs/linux-gpib-modules/linux-gpib-modules-4.3.5.ebuild b/sci-libs/linux-gpib-modules/linux-gpib-modules-4.3.5.ebuild
new file mode 100644
index 000000000000..b3f224d27e73
--- /dev/null
+++ b/sci-libs/linux-gpib-modules/linux-gpib-modules-4.3.5.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info linux-mod
+
+DESCRIPTION="Kernel modules for GPIB (IEEE 488.2) hardware"
+HOMEPAGE="https://linux-gpib.sourceforge.io/"
+SRC_URI="mirror://sourceforge/linux-gpib/linux-gpib-${PV}.tar.gz"
+S="${WORKDIR}/linux-gpib-kernel-${PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug"
+
+COMMONDEPEND=""
+RDEPEND="${COMMONDEPEND}
+	acct-group/gpib
+"
+DEPEND="${COMMONDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	# don't fix debian bugs if they break gentoo
+	"${FILESDIR}/${PN}-4.3.4-depmod.patch"
+)
+
+pkg_setup() {
+	linux-mod_pkg_setup
+
+	if kernel_is -lt 2 6 8; then
+		die "Kernel versions older than 2.6.8 are not supported."
+	fi
+}
+
+src_unpack() {
+	default
+	unpack "${WORKDIR}/linux-gpib-${PV}/linux-gpib-kernel-${PV}.tar.gz"
+}
+
+src_configure() {
+	set_arch_to_kernel
+
+	my_gpib_makeopts=''
+	use debug && my_gpib_makeopts+='GPIB-DEBUG=1 '
+
+	my_gpib_makeopts+="LINUX_SRCDIR=${KERNEL_DIR} "
+}
+
+src_compile() {
+	set_arch_to_kernel
+	emake \
+		${my_gpib_makeopts}
+}
+
+src_install() {
+	set_arch_to_kernel
+	emake \
+		DESTDIR="${ED}" \
+		INSTALL_MOD_PATH="${ED}" \
+		DEPMOD="/bin/true" \
+		docdir="${ED}/usr/share/doc/${PF}/html" \
+		${my_gpib_makeopts} \
+		install
+
+	dodoc ChangeLog AUTHORS README* NEWS
+}
-- 
cgit v1.2.3-65-gdbad