From 1b1b577bb33b34295e8cad2294c5486ee50200cf Mon Sep 17 00:00:00 2001
From: Alfredo Tupone <tupone@gentoo.org>
Date: Wed, 30 Nov 2022 19:12:11 +0100
Subject: sci-libs/pytorch: fix CVE-2022-45907

Bug: https://bugs.gentoo.org/883381
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>
---
 sci-libs/pytorch/pytorch-1.12.0-r1.ebuild | 57 +++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 sci-libs/pytorch/pytorch-1.12.0-r1.ebuild

(limited to 'sci-libs/pytorch/pytorch-1.12.0-r1.ebuild')

diff --git a/sci-libs/pytorch/pytorch-1.12.0-r1.ebuild b/sci-libs/pytorch/pytorch-1.12.0-r1.ebuild
new file mode 100644
index 000000000000..02fa58c7ba75
--- /dev/null
+++ b/sci-libs/pytorch/pytorch-1.12.0-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Tensors and Dynamic neural networks in Python"
+HOMEPAGE="https://pytorch.org/"
+SRC_URI="https://github.com/pytorch/${PN}/archive/refs/tags/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+RESTRICT="test"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+RDEPEND="
+	${PYTHON_DEPS}
+	~sci-libs/caffe2-${PV}[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	eapply \
+		"${FILESDIR}"/0002-Don-t-build-libtorch-again-for-PyTorch-1.7.1.patch \
+		"${FILESDIR}"/pytorch-1.9.0-Change-library-directory-according-to-CMake-build.patch \
+		"${FILESDIR}"/${PN}-1.6.0-global-dlopen.patch \
+		"${FILESDIR}"/pytorch-1.7.1-torch_shm_manager.patch \
+		"${FILESDIR}"/pytorch-1.12.0-CVE-2022-45907.patch
+
+	# Set build dir for pytorch's setup
+	sed -i \
+		-e "/BUILD_DIR/s|build|/var/lib/caffe2/|" \
+		tools/setup_helpers/env.py \
+		|| die
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	PYTORCH_BUILD_VERSION=${PV} \
+	PYTORCH_BUILD_NUMBER=0 \
+	USE_SYSTEM_LIBS=ON \
+	CMAKE_BUILD_DIR="${BUILD_DIR}" \
+	BUILD_DIR= \
+	distutils-r1_src_compile
+}
+
+src_install() {
+	USE_SYSTEM_LIBS=ON distutils-r1_src_install
+}
-- 
cgit v1.2.3-65-gdbad