From f8271ad740bd57ef962b39604429920477e1f0cb Mon Sep 17 00:00:00 2001
From: Arthur Zamarin <arthurzam@gentoo.org>
Date: Mon, 13 Sep 2021 12:58:09 +0300
Subject: sys-auth/seatd: fix compiling

Closes: https://bugs.gentoo.org/812929
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
---
 sys-auth/seatd/seatd-0.6.0-r1.ebuild | 55 ++++++++++++++++++++++++++++++++++++
 sys-auth/seatd/seatd-0.6.0.ebuild    | 53 ----------------------------------
 sys-auth/seatd/seatd-9999.ebuild     |  6 ++--
 3 files changed, 59 insertions(+), 55 deletions(-)
 create mode 100644 sys-auth/seatd/seatd-0.6.0-r1.ebuild
 delete mode 100644 sys-auth/seatd/seatd-0.6.0.ebuild

(limited to 'sys-auth/seatd')

diff --git a/sys-auth/seatd/seatd-0.6.0-r1.ebuild b/sys-auth/seatd/seatd-0.6.0-r1.ebuild
new file mode 100644
index 000000000000..8513ea785669
--- /dev/null
+++ b/sys-auth/seatd/seatd-0.6.0-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson systemd
+
+DESCRIPTION="Minimal seat management daemon and universal library"
+HOMEPAGE="https://sr.ht/~kennylevinsen/seatd"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.sr.ht/~kennylevinsen/seatd"
+else
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+	SRC_URI="https://git.sr.ht/~kennylevinsen/seatd/archive/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+LICENSE="MIT"
+SLOT="0/1"
+IUSE="builtin elogind +server systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	elogind? ( sys-auth/elogind )
+	systemd? ( sys-apps/systemd )
+"
+RDEPEND="${DEPEND}"
+BDEPEND=">=app-text/scdoc-1.9.7"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=enabled
+		-Dwerror=false
+		$(meson_feature builtin libseat-builtin)
+		$(meson_feature server)
+	)
+
+	if use elogind ; then
+		emesonargs+=( -Dlibseat-logind=elogind )
+	elif use systemd; then
+		emesonargs+=( -Dlibseat-logind=systemd )
+	else
+		emesonargs+=( -Dlibseat-logind=disabled )
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use server; then
+		newinitd "${FILESDIR}/seatd.initd" seatd
+		systemd_dounit contrib/systemd/seatd.service
+	fi
+}
diff --git a/sys-auth/seatd/seatd-0.6.0.ebuild b/sys-auth/seatd/seatd-0.6.0.ebuild
deleted file mode 100644
index 4191667845af..000000000000
--- a/sys-auth/seatd/seatd-0.6.0.ebuild
+++ /dev/null
@@ -1,53 +0,0 @@
-# Copyright 2020-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit meson systemd
-
-DESCRIPTION="Minimal seat management daemon and universal library"
-HOMEPAGE="https://sr.ht/~kennylevinsen/seatd"
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://git.sr.ht/~kennylevinsen/seatd"
-else
-	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
-	SRC_URI="https://git.sr.ht/~kennylevinsen/seatd/archive/${PV}.tar.gz -> ${P}.tar.gz"
-fi
-LICENSE="MIT"
-SLOT="0/1"
-IUSE="builtin elogind +server systemd"
-REQUIRED_USE="?? ( elogind systemd )"
-
-DEPEND="
-	elogind? ( sys-auth/elogind )
-	systemd? ( sys-apps/systemd )
-"
-RDEPEND="${DEPEND}"
-BDEPEND=">=app-text/scdoc-1.9.7"
-
-src_configure() {
-	local emesonargs=(
-		-Dman-pages=enabled
-		-Dwerror=false
-		$(meson_feature builtin libseat-builtin)
-		$(meson_feature server)
-	)
-
-	if use elogind || use systemd; then
-		emesonargs+=( -Dlibseat-logind=enabled )
-	else
-		emesonargs+=( -Dlibseat-logind=disabled )
-	fi
-
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-
-	if use server; then
-		newinitd "${FILESDIR}/seatd.initd" seatd
-		systemd_dounit contrib/systemd/seatd.service
-	fi
-}
diff --git a/sys-auth/seatd/seatd-9999.ebuild b/sys-auth/seatd/seatd-9999.ebuild
index 4191667845af..8513ea785669 100644
--- a/sys-auth/seatd/seatd-9999.ebuild
+++ b/sys-auth/seatd/seatd-9999.ebuild
@@ -34,8 +34,10 @@ src_configure() {
 		$(meson_feature server)
 	)
 
-	if use elogind || use systemd; then
-		emesonargs+=( -Dlibseat-logind=enabled )
+	if use elogind ; then
+		emesonargs+=( -Dlibseat-logind=elogind )
+	elif use systemd; then
+		emesonargs+=( -Dlibseat-logind=systemd )
 	else
 		emesonargs+=( -Dlibseat-logind=disabled )
 	fi
-- 
cgit v1.2.3