From 9b829b2af2dc1684e5608627451ba48308cd9a54 Mon Sep 17 00:00:00 2001
From: Craig Andrews <candrews@gentoo.org>
Date: Thu, 12 Nov 2020 10:58:41 -0500
Subject: sys-devel/llvm-roc: Version bump to 3.9.0

Closes: https://github.com/gentoo/gentoo/pull/18186
Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Craig Andrews <candrews@gentoo.org>
---
 sys-devel/llvm-roc/llvm-roc-3.9.0.ebuild | 70 ++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 sys-devel/llvm-roc/llvm-roc-3.9.0.ebuild

(limited to 'sys-devel/llvm-roc/llvm-roc-3.9.0.ebuild')

diff --git a/sys-devel/llvm-roc/llvm-roc-3.9.0.ebuild b/sys-devel/llvm-roc/llvm-roc-3.9.0.ebuild
new file mode 100644
index 000000000000..8bcc3f8ce0eb
--- /dev/null
+++ b/sys-devel/llvm-roc/llvm-roc-3.9.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Radeon Open Compute llvm,lld,clang"
+HOMEPAGE="https://github.com/RadeonOpenCompute/ROCm/"
+SRC_URI="https://github.com/RadeonOpenCompute/llvm-project/archive/rocm-${PV}.tar.gz -> llvm-rocm-ocl-${PV}.tar.gz"
+
+LICENSE="UoI-NCSA rc BSD public-domain"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug runtime"
+
+RDEPEND="virtual/cblas
+	dev-libs/libxml2
+	sys-libs/zlib
+	sys-libs/ncurses:="
+DEPEND="${RDEPEND}"
+PDEPEND="dev-libs/rocr-runtime"
+
+S="${WORKDIR}/llvm-project-rocm-${PV}/llvm"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.7.0-current_pos.patch"
+)
+
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+src_prepare() {
+	cd "${WORKDIR}/llvm-project-rocm-${PV}" || die
+	eapply "${FILESDIR}/${PN}-3.0.0-add_libraries.patch"
+	eapply_user
+	cmake_src_prepare
+}
+
+src_configure() {
+	PROJECTS="clang;lld"
+
+	if usex runtime; then
+		PROJECTS+=";compiler-rt"
+	fi
+
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr/lib/llvm/roc"
+		-DLLVM_ENABLE_PROJECTS="${PROJECTS}"
+		-DLLVM_TARGETS_TO_BUILD="AMDGPU;X86"
+		-DLLVM_BUILD_DOCS=NO
+		-DLLVM_ENABLE_OCAMLDOC=OFF
+		-DLLVM_ENABLE_SPHINX=NO
+		-DLLVM_ENABLE_DOXYGEN=OFF
+		-DLLVM_INSTALL_UTILS=ON
+		-DLLVM_VERSION_SUFFIX=roc
+		-DOCAMLFIND=NO
+	)
+
+	use debug || local -x CPPFLAGS="${CPPFLAGS} -DNDEBUG"
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	cat > "99${PN}" <<-EOF
+		LDPATH="${EROOT}/usr/lib/llvm/roc/lib"
+	EOF
+	doenvd "99${PN}"
+}
-- 
cgit v1.2.3-65-gdbad