From 063e59b9f8fe894995b8514523f2c6b69a4efc72 Mon Sep 17 00:00:00 2001
From: Yixun Lan <dlan@gentoo.org>
Date: Wed, 21 Dec 2016 06:49:32 +0800
Subject: sys-process/criu: version bump

Package-Manager: Portage-2.3.3, Repoman-2.3.1
---
 sys-process/criu/criu-2.9.ebuild | 96 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 96 insertions(+)
 create mode 100644 sys-process/criu/criu-2.9.ebuild

(limited to 'sys-process/criu/criu-2.9.ebuild')

diff --git a/sys-process/criu/criu-2.9.ebuild b/sys-process/criu/criu-2.9.ebuild
new file mode 100644
index 000000000000..779320cb41f3
--- /dev/null
+++ b/sys-process/criu/criu-2.9.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils toolchain-funcs linux-info flag-o-matic python-r1 python-utils-r1
+
+DESCRIPTION="utility to checkpoint/restore a process tree"
+HOMEPAGE="http://criu.org/"
+SRC_URI="http://download.openvz.org/criu/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64"
+IUSE="python setproctitle"
+
+RDEPEND="dev-libs/protobuf-c
+	dev-libs/libnl:3
+	sys-libs/libcap
+	python? ( ${PYTHON_DEPS} )
+	setproctitle? ( dev-libs/libbsd )"
+DEPEND="${RDEPEND}
+	app-text/asciidoc
+	app-text/xmlto"
+RDEPEND="${RDEPEND}
+	python? (
+		dev-libs/protobuf[python,${PYTHON_USEDEP}]
+		dev-python/ipaddr[${PYTHON_USEDEP}]
+	)"
+
+CONFIG_CHECK="~CHECKPOINT_RESTORE ~NAMESPACES ~PID_NS ~FHANDLE ~EVENTFD ~EPOLL ~INOTIFY_USER
+	~IA32_EMULATION ~UNIX_DIAG ~INET_DIAG ~INET_UDP_DIAG ~PACKET_DIAG ~NETLINK_DIAG"
+
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}"/2.2/${PN}-2.2-flags.patch
+	"${FILESDIR}"/2.9/${PN}-2.9-makefile.patch
+	"${FILESDIR}"/2.3/${PN}-2.3-no-git.patch
+	"${FILESDIR}"/${PN}-2.8-automagic-libbsd.patch
+	"${FILESDIR}"/2.0/${PN}-2.0-sysroot.patch
+	"${FILESDIR}"/2.3/${PN}-2.3-aarch64.patch
+)
+
+criu_arch() {
+	# criu infers the arch from $(uname -m).  We never want this to happen.
+	case ${ARCH} in
+	amd64) echo "x86";;
+	arm64) echo "aarch64";;
+	*)     echo "${ARCH}";;
+	esac
+}
+
+src_compile() {
+	RAW_LDFLAGS="$(raw-ldflags)" emake \
+		CC="$(tc-getCC)" \
+		LD="$(tc-getLD)" \
+		OBJCOPY="$(tc-getOBJCOPY)" \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		ARCH="$(criu_arch)" \
+		V=1 WERROR=0 DEBUG=0 \
+		SETPROCTITLE=$(usex setproctitle) \
+		PYCRIU=$(usex python) \
+		all docs
+}
+
+src_test() {
+	# root privileges are required to dump all necessary info
+	if [[ ${EUID} -eq 0 ]] ; then
+		emake -j1 CC="$(tc-getCC)" ARCH="$(criu_arch)" V=1 WERROR=0 test
+	fi
+}
+
+install_crit() {
+	"${PYTHON:-python}" ../scripts/crit-setup.py install --root="${D}" --prefix="${EPREFIX}/usr/"
+}
+
+src_install() {
+	emake \
+		ARCH="$(criu_arch)" \
+		PREFIX="${EPREFIX}"/usr \
+		LOGROTATEDIR="${EPREFIX}"/etc/logrotate.d \
+		DESTDIR="${D}" \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		install
+
+	dodoc CREDITS README.md
+
+	if use python ; then
+		cd lib
+		python_foreach_impl install_crit
+	fi
+}
-- 
cgit v1.2.3-65-gdbad