From 0f9f86e6f09c09be343aaa2f1c64837f3dd7ce23 Mon Sep 17 00:00:00 2001
From: Brian Evans <grknight@gentoo.org>
Date: Thu, 7 Feb 2019 10:54:06 -0500
Subject: www-apache/mod_musicindex: Revbump for dependency and EAPI change

Closes: https://bugs.gentoo.org/666076
Package-Manager: Portage-2.3.59, Repoman-2.3.12
Signed-off-by: Brian Evans <grknight@gentoo.org>
---
 .../mod_musicindex/mod_musicindex-1.4.1-r1.ebuild  | 63 ++++++++++++++++++++++
 .../mod_musicindex/mod_musicindex-1.4.1.ebuild     | 59 --------------------
 2 files changed, 63 insertions(+), 59 deletions(-)
 create mode 100644 www-apache/mod_musicindex/mod_musicindex-1.4.1-r1.ebuild
 delete mode 100644 www-apache/mod_musicindex/mod_musicindex-1.4.1.ebuild

(limited to 'www-apache')

diff --git a/www-apache/mod_musicindex/mod_musicindex-1.4.1-r1.ebuild b/www-apache/mod_musicindex/mod_musicindex-1.4.1-r1.ebuild
new file mode 100644
index 000000000000..a033588e3669
--- /dev/null
+++ b/www-apache/mod_musicindex/mod_musicindex-1.4.1-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit apache-module
+
+DESCRIPTION="mod_musicindex allows nice displaying of directories containing music files"
+HOMEPAGE="http://www.parisc-linux.org/~varenet/musicindex/"
+SRC_URI="http://hacks.slashdirt.org/musicindex/${P}.tar.gz
+	http://validator.w3.org/feed/images/valid-rss.png -> ${P}_valid-rss.png
+	http://jigsaw.w3.org/css-validator/images/vcss -> ${P}_vcss
+	http://www.w3.org/Icons/valid-xhtml11 -> ${P}_valid-xhtml11"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+mp3 +mp4 +flac +vorbis +cache mysql archive"
+
+DEPEND="mp3? ( media-libs/libmad media-libs/libid3tag )
+	mp4? ( media-libs/libmp4v2:0 )
+	flac? ( media-libs/flac )
+	vorbis? ( media-libs/libvorbis )
+	archive? ( app-arch/libarchive )
+	mysql? ( dev-db/mysql-connector-c:0= )"
+RDEPEND="${DEPEND}
+	sys-devel/libtool"
+
+APACHE2_MOD_CONF="50_${PN}"
+APACHE2_MOD_DEFINE="MUSICINDEX"
+DOCS=( AUTHORS BUGS ChangeLog README UPGRADING )
+
+need_apache2
+
+pkg_setup() {
+	_init_apache2_late
+}
+
+src_configure() {
+	econf \
+		$(use_enable mp3) \
+		$(use_enable mp4) \
+		$(use_enable flac) \
+		$(use_enable vorbis) \
+		$(use_enable archive) \
+		$(use_enable cache filecache) \
+		$(use_enable mysql mysqlcache)
+}
+
+src_compile() {
+	default
+}
+
+src_install() {
+	default
+	apache-module_src_install
+
+	# install W3C images
+	insinto /usr/share/mod_musicindex
+	newins "${DISTDIR}/${P}_valid-rss.png" valid-rss.png
+	newins "${DISTDIR}/${P}_valid-xhtml11" valid-xhtml11
+	newins "${DISTDIR}/${P}_vcss" vcss
+}
diff --git a/www-apache/mod_musicindex/mod_musicindex-1.4.1.ebuild b/www-apache/mod_musicindex/mod_musicindex-1.4.1.ebuild
deleted file mode 100644
index d87b3ed75c33..000000000000
--- a/www-apache/mod_musicindex/mod_musicindex-1.4.1.ebuild
+++ /dev/null
@@ -1,59 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-
-inherit apache-module
-
-DESCRIPTION="mod_musicindex allows nice displaying of directories containing music files"
-HOMEPAGE="http://www.parisc-linux.org/~varenet/musicindex/"
-SRC_URI="http://hacks.slashdirt.org/musicindex/${P}.tar.gz
-	http://validator.w3.org/feed/images/valid-rss.png -> ${P}_valid-rss.png
-	http://jigsaw.w3.org/css-validator/images/vcss -> ${P}_vcss
-	http://www.w3.org/Icons/valid-xhtml11 -> ${P}_valid-xhtml11"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="+mp3 +mp4 +flac +vorbis +cache mysql archive"
-
-DEPEND="mp3? ( media-libs/libmad media-libs/libid3tag )
-	mp4? ( media-libs/libmp4v2:0 )
-	flac? ( media-libs/flac )
-	vorbis? ( media-libs/libvorbis )
-	archive? ( app-arch/libarchive )
-	mysql? ( virtual/mysql )"
-RDEPEND="${DEPEND}
-	sys-devel/libtool"
-
-APACHE2_MOD_CONF="50_${PN}"
-APACHE2_MOD_DEFINE="MUSICINDEX"
-DOCFILES="AUTHORS BUGS ChangeLog README UPGRADING"
-
-need_apache2
-
-src_configure() {
-	econf \
-		$(use_enable mp3) \
-		$(use_enable mp4) \
-		$(use_enable flac) \
-		$(use_enable vorbis) \
-		$(use_enable archive) \
-		$(use_enable cache filecache) \
-		$(use_enable mysql mysqlcache)
-}
-
-src_compile() {
-	emake || die "emake failed"
-}
-
-src_install() {
-	emake DESTDIR="${D}" install || die "emake failed"
-	apache-module_src_install
-
-	# install W3C images
-	insinto /usr/share/mod_musicindex
-	newins "${DISTDIR}/${P}_valid-rss.png" valid-rss.png
-	newins "${DISTDIR}/${P}_valid-xhtml11" valid-xhtml11
-	newins "${DISTDIR}/${P}_vcss" vcss
-}
-- 
cgit v1.2.3-65-gdbad