From c17c75b84bb3f4d3857c6430a8b02461f9671c3c Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Sun, 2 Feb 2020 11:20:32 +0100
Subject: x11-misc/gtkdialog: Call xdg_icon_cache_update()

Package-Manager: Portage-2.3.86, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 x11-misc/gtkdialog/gtkdialog-0.8.3-r3.ebuild | 55 ++++++++++++++++++++++++++++
 x11-misc/gtkdialog/gtkdialog-99999.ebuild    | 12 +++++-
 2 files changed, 65 insertions(+), 2 deletions(-)
 create mode 100644 x11-misc/gtkdialog/gtkdialog-0.8.3-r3.ebuild

(limited to 'x11-misc')

diff --git a/x11-misc/gtkdialog/gtkdialog-0.8.3-r3.ebuild b/x11-misc/gtkdialog/gtkdialog-0.8.3-r3.ebuild
new file mode 100644
index 000000000000..f6947de49587
--- /dev/null
+++ b/x11-misc/gtkdialog/gtkdialog-0.8.3-r3.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools xdg-utils
+
+DESCRIPTION="A small utility for fast and easy GUI building"
+HOMEPAGE="https://code.google.com/p/gtkdialog/"
+SRC_URI="https://${PN}.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="glade vte"
+
+RDEPEND="
+	x11-libs/gtk+:2
+	glade? ( gnome-base/libglade )
+	vte? ( x11-libs/vte:0= )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/flex
+	virtual/yacc
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.8.3-fno-common.patch
+	"${FILESDIR}"/${PN}-0.8.3-optdeps.patch
+)
+
+src_prepare() {
+	mv configure.{in,ac} || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with glade) $(use_with vte)
+}
+
+src_install() {
+	# Stop make install from running gtk-update-icon-cache
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=true install
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
diff --git a/x11-misc/gtkdialog/gtkdialog-99999.ebuild b/x11-misc/gtkdialog/gtkdialog-99999.ebuild
index 0f60150b0f86..6a3b1eec8e20 100644
--- a/x11-misc/gtkdialog/gtkdialog-99999.ebuild
+++ b/x11-misc/gtkdialog/gtkdialog-99999.ebuild
@@ -1,8 +1,8 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-inherit autotools git-r3
+EAPI=7
+inherit autotools git-r3 xdg-utils
 
 DESCRIPTION="A small utility for fast and easy GUI building"
 HOMEPAGE="https://github.com/oshazard/gtkdialog"
@@ -54,3 +54,11 @@ src_install() {
 	emake DESTDIR="${D}" UPDATE_ICON_CACHE=true install
 	einstalldocs
 }
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3-65-gdbad