summaryrefslogtreecommitdiff
blob: 76638e8cca4ab03c8f2610faa8c5196a5b64be47 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=4
GCONF_DEBUG=no
inherit eutils gnome2

DESCRIPTION="GnomeBaker is a GTK2/Gnome cd burning application"
HOMEPAGE="https://sourceforge.net/projects/gnomebaker"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ia64 ppc ppc64 sparc x86"
IUSE="dvdr flac libnotify mp3 vorbis"

COMMON_DEPEND="app-cdr/cdrdao
	dev-libs/libxml2
	>=gnome-base/libglade-2
	>=gnome-base/libgnomeui-2
	>=media-libs/gstreamer-0.10:0.10
	virtual/cdrtools
	x11-libs/cairo
	x11-libs/gtk+:2
	dvdr? ( app-cdr/dvd+rw-tools )
	libnotify? ( x11-libs/libnotify )"
RDEPEND="${COMMON_DEPEND}
	>=media-libs/gst-plugins-good-0.10:0.10
	flac? ( >=media-plugins/gst-plugins-flac-0.10:0.10 )
	mp3? ( >=media-plugins/gst-plugins-mad-0.10:0.10 )
	vorbis? ( >=media-plugins/gst-plugins-vorbis-0.10:0.10 )"
DEPEND="${COMMON_DEPEND}
	app-text/rarian
	dev-util/intltool
	virtual/pkgconfig
	sys-devel/gettext"

src_prepare() {
	G2CONF="$(use_enable libnotify)"

	epatch \
		"${FILESDIR}"/${P}-libnotify-0.7.patch \
		"${FILESDIR}"/${P}-ldadd.patch \
		"${FILESDIR}"/${P}-seldata.patch \
		"${FILESDIR}"/${P}-mimetype.patch \
		"${FILESDIR}"/${P}-implicits.patch

	gnome2_src_prepare
}

src_install() {
	gnome2_src_install \
		gnomebakerdocdir=/usr/share/doc/${P} \
		docdir=/usr/share/gnome/help/${PN}/C \
		gnomemenudir=/usr/share/applications

	rm -rf "${ED}"/usr/share/doc/${P}/*.make "${ED}"/var
}