summaryrefslogtreecommitdiff
blob: f7ecd41d2cf5f317a41e1c662c2d7643716c3c9e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

PYTHON_COMPAT=( python{2_7,3_4,3_5} )
inherit cmake-utils python-single-r1 python-utils-r1 eutils multilib

DESCRIPTION="File transfer over OBEX for mobile phones"
HOMEPAGE="http://dev.zuckschwerdt.org/openobex/wiki/ObexFtp"
SRC_URI="mirror://sourceforge/openobex/${P}-Source.tar.gz"
SLOT="0"

LICENSE="GPL-2"
KEYWORDS="amd64 hppa ~ppc ~x86"

# bluetooth support is not really optional, bug #529068
IUSE="perl python ruby tcl" #bluetooth

RDEPEND="
	>=dev-libs/openobex-1.7
	net-wireless/bluez
	perl? ( dev-lang/perl:= )
	python? ( ${PYTHON_DEPS} )
	ruby? ( || ( dev-lang/ruby:2.1 dev-lang/ruby:2.0 ) )
	tcl? ( dev-lang/tcl:0= )
"
DEPEND="
	${RDEPEND}
	perl? ( dev-lang/swig )
	python? ( dev-lang/swig )
	ruby? ( dev-lang/swig )
	tcl? ( dev-lang/swig )
	virtual/pkgconfig
"

S=${WORKDIR}/${P}-Source

DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )

PATCHES=(
	"${FILESDIR}"/${PN}-0.23-gentoo.patch
	"${FILESDIR}"/${PN}-0.24-config.patch
	"${FILESDIR}"/${PN}-0.24-enable_bluetooth.patch
	"${FILESDIR}"/${PN}-0.24-python_sitedir.patch
	"${FILESDIR}"/${PN}-0.24-norpath.patch
	"${FILESDIR}"/${PN}-0.24-fuse.patch
	"${FILESDIR}"/${PN}-0.24-pkgconfig_requires.patch
)

src_configure() {
# -DENABLE_BLUETOOTH=$(usex bluetooth)
	local mycmakeargs=(
		-DCMAKE_BUILD_TYPE=Release
		-DCMAKE_SKIP_RPATH=ON
		-DENABLE_PERL=$(usex perl)
		-DENABLE_BLUETOOTH=yes
		-DENABLE_PYTHON=$(usex python)
		$(usex python -DPYTHON_SITE_DIR=$(python_get_sitedir) '')
		-DENABLE_RUBY=$(usex ruby)
		-DENABLE_TCL=$(usex tcl)
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	rm -rf "${ED}"/usr/share/doc/${PN}/html || die #524866
}