summaryrefslogtreecommitdiff
blob: af56c093c198cb87df91de50fb214a312080ba69 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} )

inherit bash-completion-r1 python-r1 vcs-snapshot

DESCRIPTION="change directory command that learns"
HOMEPAGE="https://github.com/joelthelion/autojump"
SRC_URI="https://github.com/joelthelion/${PN}/archive/release-v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~ppc ~ppc64"
IUSE="python test"

# Not all tests pass. Need investigation.
RESTRICT="test"
RDEPEND="python? ( ${PYTHON_DEPS} )"
DEPEND="test? ( dev-python/flake8 dev-python/tox )"

src_prepare() {
	sed -e "s: \(/etc/profile.d\): \"${EPREFIX}\1\":" \
		-e "s:/usr/local/share:/usr/share:" \
		-i bin/autojump.sh || die

	# autojump_argparse is only there for Python 2.6 compatibility
	sed -e "s:autojump_argparse:argparse:" \
		-i bin/autojump || die

	# upstream fixes to the autojump.fish script; the first patch is needed for
	# the second patch to apply
	epatch "${FILESDIR}/autojump-22.4.4-fix-autojump.fish-bugs.patch"
	epatch "${FILESDIR}/autojump-22.4.4-fix-__aj_error-typo.patch"
}

src_compile() {
	:
}

src_install() {
	dobin bin/autojump
	python_replicate_script "${ED}"/usr/bin/autojump

	insinto /etc/profile.d
	doins bin/"${PN}".sh

	insinto /usr/share/"${PN}"/
	doins bin/"${PN}.bash"
	doins bin/"${PN}.zsh"
	doins bin/"${PN}.fish"
	insinto /usr/share/zsh/site-functions
	doins bin/_j

	python_foreach_impl python_domodule bin/autojump_data.py bin/autojump_utils.py
	if use python; then
		python_foreach_impl python_domodule tools/autojump_ipython.py
		einfo 'This tool provides "j" for ipython, please add'
		einfo '"import autojump_ipython" to your ipy_user_conf.py.'
	fi

	doman docs/"${PN}.1"
	dodoc README.md
}

pkg_postinst() {
	elog 'If you use app-shells/fish, add the following code to your'
	elog 'config.fish to get autojump support:'
	elog 'if test -f /usr/share/autojump/autojump.fish'
	elog '    source /usr/share/autojump/autojump.fish'
	elog 'end'
}