blob: 6b94964a1fd4fc23190271aeb7381515946f0b5c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit flag-o-matic
MY_PN="MoarVM"
if [[ ${PV} == "9999" ]]; then
EGIT_REPO_URI="https://github.com/${MY_PN}/${MY_PN}.git"
inherit git-r3
KEYWORDS=""
S="${WORKDIR}/${P}"
else
SRC_URI="http://moarvm.org/releases/${MY_PN}-${PV}.tar.gz"
KEYWORDS="~amd64 ~x86"
S="${WORKDIR}/${MY_PN}-${PV}"
fi
DESCRIPTION="A 6model-based VM for NQP and Rakudo Perl 6"
HOMEPAGE="http://moarvm.org"
LICENSE="Artistic-2"
SLOT="0"
#USE=optimize triggers makefile bug
IUSE="asan clang debug doc +jit static-libs ubsan"
RDEPEND="dev-libs/libatomic_ops
>=dev-libs/libuv-1.26
dev-lang/lua:=
virtual/libffi"
DEPEND="${RDEPEND}
clang? ( >=sys-devel/clang-3.1 )
dev-lang/perl"
DOCS=( CREDITS README.markdown )
# Tests are conducted via nqp
RESTRICT=test
# known configure bug
PATCHES="${FILESDIR}/fix-quoting.patch"
src_configure() {
MAKEOPTS+=" NOISY=1"
use doc && DOCS+=( docs/* )
local prefix="${EPREFIX}/usr"
local libdir="${EPREFIX}/usr/$(get_libdir)"
einfo "--prefix '${prefix}'"
einfo "--libdir '${libdir}'"
local myconfigargs=(
"--prefix" "${prefix}"
"--has-libuv"
"--has-libatomic_ops"
"--has-libffi"
"--libdir" "${libdir}"
"--compiler" "$(usex clang clang gcc)"
"$(usex asan --asan)"
"$(usex debug --debug --no-debug)"
"$(usex static-libs --static)"
"$(usex ubsan --ubsan)"
)
perl Configure.pl "${myconfigargs[@]}" moarshared || die
}
|
GitWeb
