blob: 10bfdfee32ac8871dda09381a5bb5033b209fe3b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=5
inherit autotools eutils multilib prefix toolchain-funcs versionator virtualx
MY_P="${PN}${PV/_beta/b}"
DESCRIPTION="Tk Widget Set"
HOMEPAGE="http://www.tcl.tk/"
SRC_URI="mirror://sourceforge/tcl/${MY_P}-src.tar.gz"
LICENSE="tcltk"
SLOT="0/8.5"
KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="debug threads truetype aqua xscreensaver"
RDEPEND="
!aqua? (
media-libs/fontconfig
media-libs/freetype:2
x11-libs/libX11
x11-libs/libXt
truetype? ( x11-libs/libXft )
xscreensaver? ( x11-libs/libXScrnSaver )
)
~dev-lang/tcl-${PV}:0="
DEPEND="${RDEPEND}
!aqua? ( x11-base/xorg-proto )"
SPARENT="${WORKDIR}/${MY_P}"
S="${SPARENT}"/unix
src_prepare() {
epatch \
"${FILESDIR}"/${PN}-8.5.11-fedora-xft.patch \
"${FILESDIR}"/${PN}-8.5.13-multilib.patch
epatch "${FILESDIR}"/${PN}-8.4.15-aqua.patch
eprefixify Makefile.in
# Bug 125971
epatch "${FILESDIR}"/${PN}-8.5.14-conf.patch
# Bug 648570
epatch "${FILESDIR}"/${PN}-8.6.8-libieee.patch
# Make sure we use the right pkg-config, and link against fontconfig
# (since the code base uses Fc* functions).
sed \
-e 's/FT_New_Face/XftFontOpen/g' \
-e "s:\<pkg-config\>:$(tc-getPKG_CONFIG):" \
-e 's:xft freetype2:xft freetype2 fontconfig:' \
-i configure.in || die
rm -f configure || die
sed \
-e '/chmod/s:555:755:g' \
-i Makefile.in || die
tc-export CC
eautoconf
}
src_configure() {
local mylibdir=$(get_libdir)
econf \
--with-tcl="${EPREFIX}/usr/${mylibdir}" \
$(use_enable threads) \
$(use_enable aqua) \
$(use_enable truetype xft) \
$(use_enable xscreensaver xss) \
$(use_enable debug symbols)
}
src_test() {
Xemake test
}
src_install() {
#short version number
local v1=$(get_version_component_range 1-2)
local mylibdir=$(get_libdir)
S= default
# normalize $S path, bug #280766 (pkgcore)
local nS="$(cd "${S}"; pwd)"
# fix the tkConfig.sh to eliminate refs to the build directory
# and drop unnecessary -L inclusion to default system libdir
sed \
-e "/^TK_BUILD_LIB_SPEC=/s:-L${SPARENT}.*unix *::g" \
-e "/^TK_LIB_SPEC=/s:-L${EPREFIX}/usr/${mylibdir} *::g" \
-e "/^TK_SRC_DIR=/s:${SPARENT}:${EPREFIX}/usr/${mylibdir}/tk${v1}/include:g" \
-e "/^TK_BUILD_STUB_LIB_SPEC=/s:-L${SPARENT}.*unix *::g" \
-e "/^TK_STUB_LIB_SPEC=/s:-L${EPREFIX}/usr/${mylibdir} *::g" \
-e "/^TK_BUILD_STUB_LIB_PATH=/s:${SPARENT}.*unix:${EPREFIX}/usr/${mylibdir}:g" \
-e "/^TK_LIB_FILE=/s:'libtk${v1}..TK_DBGX..so':\"libk${v1}\$\{TK_DBGX\}.so\":g" \
-i "${ED}"/usr/${mylibdir}/tkConfig.sh || die
if use prefix && [[ ${CHOST} != *-darwin* && ${CHOST} != *-mint* ]] ; then
sed \
-e "/^TK_CC_SEARCH_FLAGS=/s|'$|:${EPREFIX}/usr/${mylibdir}'|g" \
-e "/^TK_LD_SEARCH_FLAGS=/s|'$|:${EPREFIX}/usr/${mylibdir}'|" \
-i "${ED}"/usr/${mylibdir}/tkConfig.sh || die
fi
# install private headers
insinto /usr/${mylibdir}/tk${v1}/include/unix
doins "${S}"/*.h
insinto /usr/${mylibdir}/tk${v1}/include/generic
doins "${SPARENT}"/generic/*.h
rm -f "${ED}"/usr/${mylibdir}/tk${v1}/include/generic/{tk,tkDecls,tkPlatDecls}.h || die
# install symlink for libraries
dosym libtk${v1}$(get_libname) /usr/${mylibdir}/libtk$(get_libname)
dosym libtkstub${v1}.a /usr/${mylibdir}/libtkstub.a
dosym wish${v1} /usr/bin/wish
dodoc "${SPARENT}"/{ChangeLog*,README,changes}
}
|
GitWeb