blob: ca2cbc01644227f3ecf22941c9743cab1b2f3c40 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit autotools
DESCRIPTION="A C++ class library for writing CGI applications"
HOMEPAGE="https://www.gnu.org/software/cgicc/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
LICENSE="LGPL-3 doc? ( FDL-1.2 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples static-libs"
RDEPEND=""
DEPEND="doc? ( app-doc/doxygen )"
PATCHES=(
"${FILESDIR}/3.2.10-fix-pkgconfig.patch"
"${FILESDIR}/${PN}-3.2.16-fix-doc-building.patch"
)
src_prepare() {
default
eautoreconf
}
src_configure() {
econf \
$(use_enable examples demos) \
$(use_enable doc) \
$(use_enable static-libs static)
}
src_install() {
default
# package provides .pc files
find "${D}" -name '*.la' -delete || die
if use examples; then
docinto examples
dodoc {contrib,demo}/{*.{cpp,h},*.cgi,README}
docompress -x /usr/share/doc/${PF}/examples
fi
}
|
GitWeb
