summaryrefslogtreecommitdiff
blob: c8144619bb69c9c81bdb8219194104d3000a31ad (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
# Copyright 2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python3_6 )
inherit python-any-r1 cmake-utils

DESCRIPTION="CBOR protocol implementation for C and others"
HOMEPAGE="https://github.com/pjk/libcbor"
SRC_URI="https://github.com/PJK/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0/0"
KEYWORDS="~amd64 ~x86"
IUSE="+custom-alloc doc test"

BDEPEND="
	doc? (
		$(python_gen_any_dep '
			dev-python/sphinx[${PYTHON_USEDEP}]
			dev-python/breathe[${PYTHON_USEDEP}]
		')
	)
"

RESTRICT="!test? ( test )"

CMAKE_MAKEFILE_GENERATOR="emake"

python_check_deps() {
	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
		has_version "dev-python/breathe[${PYTHON_USEDEP}]"
}

pkg_setup() {
	use doc && python-any-r1_pkg_setup
}

src_configure() {
	local -a mycmakeargs=(
		-DCMAKE_BUILD_TYPE=Release
		-DCBOR_CUSTOM_ALLOC=$(usex custom-alloc 'ON' 'OFF')
		-DWITH_TESTS=$(usex test 'ON' 'OFF')
	)

	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile

	if use doc; then
		pushd doc >/dev/null || die
		emake html man
		popd >/dev/null || die
	fi
}

src_install() {
	cmake-utils_src_install

	if use doc; then
		dodoc -r doc/build/html
		doman doc/build/man/*
	fi
}