summaryrefslogtreecommitdiff
blob: a6f3fe1220f242592fe5a26b91bfbe554f2f0287 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

DESCRIPTION="C++ MIME library designed to be easy to use and integrate, fast and efficient."
HOMEPAGE="http://www.codesink.org/mimetic_mime_library.html"
SRC_URI="http://www.codesink.org/download/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples"

DEPEND="doc? ( app-doc/doxygen )"

src_prepare() {
	default

	sed -i -e "s|../doxygen.css|doxygen.css|" doc/header.html || die
}

src_configure() {
	econf --disable-static
}

src_compile() {
	default
	use doc && emake -C doc docs
}

src_install() {
	default

	use doc && dodoc -r doc/html/

	if use examples ; then
		docinto examples
		dodoc examples/{README,TODO,test.msg,*.cxx,*.h}
	fi

	rm "${D}"/usr/$(get_libdir)/libmimetic.la || die
}